Introduction

Maple allows you to create nested procedure definitions.  This means that procedures can be defined within other procedures, or return procedures as expected output.  Lexical scoping allows a nested procedure to access the variables which are located in surrounding procedures. You can now program in Maple and achieve better encapsulation.

In previous versions of Maple, it was difficult to have a nested procedure access the variables of an enclosing procedure.  Procedures could only share variables if the variables were global.

An Example

The simple example in this section uses the concept of lexical scoping of parameters to define a procedure that creates new procedures that depend upon the input to the top-level procedure.

makeincr := proc(n::integer) # outer procedure
        local   incr;

        incr := proc(i::integer) # inner procedure
                RETURN( i + n ); # n is the parameter to makeincr
        end;
        RETURN( incr );
end;

$\mathrm{makeincr}:=\mathbf{proc}\left(n::\mathrm{integer}\right)\mathbf{local}\mathrm{incr}\;\mathrm{incr}:=\mathbf{proc}\left(i::\mathrm{integer}\right)\mathrm{RETURN}\left(i\+n\right)\mathbf{end\; proc}\;\mathrm{RETURN}\left(\mathrm{incr}\right)\mathbf{end\; proc}$

add2 := makeincr( 2 );

$\mathrm{add2}≔\mathrm{incr}$

add2( 0 );

$2$

add2( 5 );

$7$

addminus1 := makeincr( -1 );

$\mathrm{addminus1}≔\mathrm{incr}$

addminus1( 0 );

$\mathrm{-1}$

addminus1( 5 );

$4$

In the preceding example, a procedure incr is nested in an outer procedure makeincr.  The outer procedure returns as its value the nested procedure incr. The parameter n of makeincr is lexically scoped: its value is visible within the inner procedure incr, where it is used to determine by how much to increment its own parameter i. The value of  n is passed to makeincr as part of the definition of the inner procedure incr.

Notice that if one sets the kernel options variable warnlevel to 4, a warning is issued about the presence of a lexically scoped parameter.  The warning identifies the new feature in Release 5, whereas in previous versions of Maple, the variable n occurring in the definition of the inner procedure incr would be regarded as a global variable.

For more information about lexical scoping, please see the lexical example worksheet.

The DEtools package is not new in Release 5, but it has been significantly expanded, with dramatic improvements both in performance and power. DEtools incorporated packages that were previously share packages: ODEtools (here DEtools,Lie) for computing using Lie symmetry methods and classifying ODEs; diffop , for computing with linear differential operators; and Poincare for plotting 2D/3D projections of Poincare sections of Hamiltonian systems.

The dsolve command has also been rewritten to take direct advantage of the new implementation of symmetry methods now available in DEtools, resulting in a remarkable improvement in its solving performance.

Finally, the odeadvisor command, originally from ODEtools, can be used to classify ODEs in general, and contains more help pages with related information and solving tips.

Many more examples can be found in the example worksheets examples/diffop and examples/linearode.

with( DEtools );

$\left[\mathrm{AreSimilar}\,\mathrm{Closure}\,\mathrm{DEnormal}\,\mathrm{DEplot}\,\mathrm{DEplot3d}\,\mathrm{DEplot\_polygon}\,\mathrm{DFactor}\,\mathrm{DFactorLCLM}\,\mathrm{DFactorsols}\,\mathrm{Dchangevar}\,\mathrm{Desingularize}\,\mathrm{FindODE}\,\mathrm{FunctionDecomposition}\,\mathrm{GCRD}\,\mathrm{Gosper}\,\mathrm{Heunsols}\,\mathrm{Homomorphisms}\,\mathrm{IVPsol}\,\mathrm{IsHyperexponential}\,\mathrm{LCLM}\,\mathrm{MeijerGsols}\,\mathrm{MultiplicativeDecomposition}\,\mathrm{ODEInvariants}\,\mathrm{PDEchangecoords}\,\mathrm{PolynomialNormalForm}\,\mathrm{RationalCanonicalForm}\,\mathrm{ReduceHyperexp}\,\mathrm{RiemannPsols}\,\mathrm{Xchange}\,\mathrm{Xcommutator}\,\mathrm{Xgauge}\,\mathrm{Zeilberger}\,\mathrm{abelsol}\,\mathrm{adjoint}\,\mathrm{autonomous}\,\mathrm{bernoullisol}\,\mathrm{buildsol}\,\mathrm{buildsym}\,\mathrm{canoni}\,\mathrm{caseplot}\,\mathrm{casesplit}\,\mathrm{checkrank}\,\mathrm{chinisol}\,\mathrm{clairautsol}\,\mathrm{constcoeffsols}\,\mathrm{convertAlg}\,\mathrm{convertsys}\,\mathrm{dalembertsol}\,\mathrm{dcoeffs}\,\mathrm{de2diffop}\,\mathrm{dfieldplot}\,\mathrm{diff\_table}\,\mathrm{diffop2de}\,\mathrm{dperiodic\_sols}\,\mathrm{dpolyform}\,\mathrm{dsubs}\,\mathrm{eigenring}\,\mathrm{endomorphism\_charpoly}\,\mathrm{equinv}\,\mathrm{eta\_k}\,\mathrm{eulersols}\,\mathrm{exactsol}\,\mathrm{expsols}\,\mathrm{exterior\_power}\,\mathrm{firint}\,\mathrm{firtest}\,\mathrm{formal\_sol}\,\mathrm{gen\_exp}\,\mathrm{generate\_ic}\,\mathrm{genhomosol}\,\mathrm{gensys}\,\mathrm{hamilton\_eqs}\,\mathrm{hypergeometricsols}\,\mathrm{hypergeomsols}\,\mathrm{hyperode}\,\mathrm{indicialeq}\,\mathrm{infgen}\,\mathrm{initialdata}\,\mathrm{integrate\_sols}\,\mathrm{intfactor}\,\mathrm{invariants}\,\mathrm{kovacicsols}\,\mathrm{leftdivision}\,\mathrm{liesol}\,\mathrm{line\_int}\,\mathrm{linearsol}\,\mathrm{matrixDE}\,\mathrm{matrix\_riccati}\,\mathrm{maxdimsystems}\,\mathrm{moser\_reduce}\,\mathrm{muchange}\,\mathrm{mult}\,\mathrm{mutest}\,\mathrm{newton\_polygon}\,\mathrm{normalG2}\,\mathrm{ode\_int\_y}\,\mathrm{ode\_y1}\,\mathrm{odeadvisor}\,\mathrm{odepde}\,\mathrm{parametricsol}\,\mathrm{particularsol}\,\mathrm{phaseportrait}\,\mathrm{poincare}\,\mathrm{polysols}\,\mathrm{power\_equivalent}\,\mathrm{rational\_equivalent}\,\mathrm{ratsols}\,\mathrm{redode}\,\mathrm{reduceOrder}\,\mathrm{reduce\_order}\,\mathrm{regular\_parts}\,\mathrm{regularsp}\,\mathrm{remove\_RootOf}\,\mathrm{riccati\_system}\,\mathrm{riccatisol}\,\mathrm{rifread}\,\mathrm{rifsimp}\,\mathrm{rightdivision}\,\mathrm{rtaylor}\,\mathrm{separablesol}\,\mathrm{singularities}\,\mathrm{solve\_group}\,\mathrm{super\_reduce}\,\mathrm{symgen}\,\mathrm{symmetric\_power}\,\mathrm{symmetric\_product}\,\mathrm{symtest}\,\mathrm{transinv}\,\mathrm{translate}\,\mathrm{untranslate}\,\mathrm{varparam}\,\mathrm{zoom}\right]$

As an example, consider the following second order, nonlinear ODE.

ode := x^4 * diff( y( x ), x, x ) + ( x * diff( y( x ), x ) - y( x ) )^3 = 0;

$\mathrm{ode}≔x^4\left(\frac{{\ⅆ}^2}{\ⅆx^2}y\left(x\right)\right)+{\left(x\left(\frac{\ⅆ}{\ⅆx}y\left(x\right)\right)-y\left(x\right)\right)}^3=0$

The new odeadvisor command, classifies this differential equation as follows

odeadvisor( ode );

$\left[\left[\mathrm{\_2nd\_order}\,\mathrm{\_with\_linear\_symmetries}\right]\right]$

Given the additional, optional argument help, odeadvisor will pop up a related help page.

odeadvisor( ode, 'help' );

$\left[\left[\mathrm{\_2nd\_order}\,\mathrm{\_with\_linear\_symmetries}\right]\right]$

The result from odeadvisor indicates that this is a second order ODE with linear symmetries. You can see the symmetries of this ODE using the symgen command (see DEtools,Lie)

symgen( ode );

$\left[\mathrm{\_\ξ}=0\,\mathrm{\_\η}=x\right],\left[\mathrm{\_\ξ}=x\,\mathrm{\_\η}=y\right]$

The dsolve command, based on this information, will solve this ODE as follows (see dsolve,Lie)

dsolve( ode );

$y\left(x\right)=\left(-\arctan \left(\frac{1}{\sqrt{\mathrm{c\_\_1}{x}^2-1}}\right)+\mathrm{c\_\_2}\right)x,y\left(x\right)=\left(\arctan \left(\frac{1}{\sqrt{\mathrm{c\_\_1}{x}^2-1}}\right)+\mathrm{c\_\_2}\right)x$

Most of the steps of the symmetry scheme are available as user-level commands. Consider for instance the symmetry cycle.

1) A pair of infinitesimals:

sym := [_xi = 0, _eta = exp(y)/ln(x)];

$\mathrm{sym}≔\left[\mathrm{\_\ξ}=0\,\mathrm{\_\η}=\frac{{\ⅇ}^y}{\ln \left(x\right)}\right]$

2) The most general first order ODE invariant under the symmetry group represented by the infinitesimals above can be obtained using equinv

ODE := equinv( sym, y(x) );

$\mathrm{ODE}≔\frac{\ⅆ}{\ⅆx}y\left(x\right)=\frac{1}{\ln \left(x\right)x}+{\ⅇ}^{y\left(x\right)}\mathrm{f\_\_1}\left(x\right)$

3) This ODE can then be solved by dsolve which calls symgen to determine the ODE symmetries and uses this information to arrive at

ans := dsolve( ODE );

$\mathrm{ans}≔y\left(x\right)=-\ln \left(-\frac{\int \ln \left(x\right)\mathrm{f\_\_1}\left(x\right)\ⅆx+\mathrm{c\_\_1}}{\ln \left(x\right)}\right)$

4) The infinitesimals of the symmetry group can in turn be reobtained departing from the solution above using buildsym

buildsym(ans, y(x));

$\left[\mathrm{\_\ξ}=0\,\mathrm{\_\η}=\frac{{\ⅇ}^y}{\ln \left(x\right)}\right]$

5) The concrete Lie group of transformation equations (changes of variables) which leaves the ODE invariant can be obtained using transinv

TR_1 := transinv( sym, y(x), s(r) );

$\mathrm{TR\_1}≔\left\{r=x\,s\left(r\right)=\ln \left(-\frac{\ln \left(x\right)}{\mathrm{\_\α}{\ⅇ}^{y\left(x\right)}-\ln \left(x\right)}\right)+y\left(x\right)\right\}$

In the above, _alpha; is the continuous parameter of the Lie group (that is, a real constant). The inverse transformation is given by

ITR_1 := solve(TR_1,{x,y(x)});

$\mathrm{ITR\_1}≔\left\{x=r\,y\left(x\right)=s\left(r\right)-\ln \left(\frac{{\ⅇ}^{s\left(r\right)}\mathrm{\_\α}+\ln \left(r\right)}{\ln \left(r\right)}\right)\right\}$

and can be used to check that the ODE is actually invariant under these transformation equations, arriving at an ODE with the same form as the original one (using dchange to change variables):

PDEtools[dchange](ITR_1, ODE, [r,s(r)], normal);

$\frac{\left(\frac{\ⅆ}{\ⅆr}s\left(r\right)\right){\ln \left(r\right)}^{2}r+{\ⅇ}^{s\left(r\right)}\mathrm{\_\α}}{\ln \left(r\right)r\left({\ⅇ}^{s\left(r\right)}\mathrm{\_\α}+\ln \left(r\right)\right)}=\frac{{\ⅇ}^{s\left(r\right)-\ln \left(\frac{{\ⅇ}^{s\left(r\right)}\mathrm{\_\α}+\ln \left(r\right)}{\ln \left(r\right)}\right)}\mathrm{f\_\_1}\left(r\right)r\ln \left(r\right)+1}{r\ln \left(r\right)}$

expand(simplify(solve((20),{diff(s(r),r)})));

$\left\{\frac{\ⅆ}{\ⅆr}s\left(r\right)={\ⅇ}^{s\left(r\right)}\mathrm{f\_\_1}\left(r\right)+\frac{1}{\ln \left(r\right)r}\right\}$

6) The canonical coordinates of this Lie group (the coordinates which reduce this ODE to a quadrature; see odeadvisor,quadrature) are obtained using canoni

TR_2 := canoni(sym,y(x),s(r));

$\mathrm{TR\_2}≔\left\{r=x\,s\left(r\right)=-\frac{\ln \left(x\right)}{{\ⅇ}^{y\left(x\right)}}\right\}$

ITR_2 := solve(TR_2,{x,y(x)});

$\mathrm{ITR\_2}≔\left\{x=r\,y\left(x\right)=\ln \left(-\frac{\ln \left(r\right)}{s\left(r\right)}\right)\right\}$

These canonical coordinates are presently used by dsolve to reduce ODE to a quadrature by change of variables

PDEtools[dchange](ITR_2,ODE,[r,s(r)],normal);

$\frac{-\left(\frac{\ⅆ}{\ⅆr}s\left(r\right)\right)\ln \left(r\right)r+s\left(r\right)}{s\left(r\right)r\ln \left(r\right)}=\frac{-{\ln \left(r\right)}^2\mathrm{f\_\_1}\left(r\right)r+s\left(r\right)}{s\left(r\right)r\ln \left(r\right)}$

expand(simplify(solve((24),{diff(s(r),r)})));

$\left\{\frac{\ⅆ}{\ⅆr}s\left(r\right)=\ln \left(r\right)\mathrm{f\_\_1}\left(r\right)\right\}$

Once the right hand side of the ODE above does not depend on s(r), it is a quadrature and is solved just integrating both sides with respect to r. Changing variables back one arrives at the answer for the original ODE returned by dsolve.

7) Finally, the infinitesimals of an underlying symmetry group can be used to build an integrating factor for this first order ODE (see odeadvisor,exact) by using the intfactor command:

ODE;

$\frac{\ⅆ}{\ⅆx}y\left(x\right)=\frac{1}{\ln \left(x\right)x}+{\ⅇ}^{y\left(x\right)}\mathrm{f\_\_1}\left(x\right)$

mu := intfactor(ODE);

$\mathrm{\mu }≔{\ⅇ}^{-y\left(x\right)}\ln \left(x\right)$

odeadvisor( mu * ODE );

$\left[\mathrm{\_exact}\,\left[\mathrm{\_1st\_order}\,\mathrm{\_with\_symmetry\_[F(x),G(x)]}\right]\right]$

There are a variety of optional arguments to dsolve (see the dsolve,Lie for details).

The PDEtools package is a new package in Maple. PDEtools is a collection of commands and routines for finding analytical solutions for partial differential equations (PDEs). The package is an implementation of known methods for solving PDEs; however, it also allows you to look for solutions of equations not yet automatically solved by the package, or for "different solutions" when the package returns a solution which is not the most general one. For this purpose, you can make use of the dchange command and of the HINT option of the pdsolve command (especially the functional hint), both explained in more detail in the corresponding help pages. Finally, PDEtools incorporates the PDEplot command, for plotting the solution for linear and nonlinear first order PDEs with given initial conditions.

with(PDEtools);

$\left[\mathrm{CanonicalCoordinates}\,\mathrm{ChangeSymmetry}\,\mathrm{CharacteristicQ}\,\mathrm{CharacteristicQInvariants}\,\mathrm{ConservedCurrentTest}\,\mathrm{ConservedCurrents}\,\mathrm{ConsistencyTest}\,\mathrm{D\_Dx}\,\mathrm{DeterminingPDE}\,\mathrm{Eta\_k}\,\mathrm{Euler}\,\mathrm{FirstIntegralSolver}\,\mathrm{FromJet}\,\mathrm{FunctionFieldSolutions}\,\mathrm{InfinitesimalGenerator}\,\mathrm{Infinitesimals}\,\mathrm{IntegratingFactorTest}\,\mathrm{IntegratingFactors}\,\mathrm{InvariantEquation}\,\mathrm{InvariantSolutions}\,\mathrm{InvariantTransformation}\,\mathrm{Invariants}\,\mathrm{Laplace}\,\mathrm{Library}\,\mathrm{PDEplot}\,\mathrm{PolynomialSolutions}\,\mathrm{ReducedForm}\,\mathrm{SimilaritySolutions}\,\mathrm{SimilarityTransformation}\,\mathrm{Solve}\,\mathrm{SymmetryCommutator}\,\mathrm{SymmetryGauge}\,\mathrm{SymmetrySolutions}\,\mathrm{SymmetryTest}\,\mathrm{SymmetryTransformation}\,\mathrm{TWSolutions}\,\mathrm{ToJet}\,\mathrm{ToMissingDependentVariable}\,\mathrm{build}\,\mathrm{casesplit}\,\mathrm{charstrip}\,\mathrm{dchange}\,\mathrm{dcoeffs}\,\mathrm{declare}\,\mathrm{diff\_table}\,\mathrm{difforder}\,\mathrm{dpolyform}\,\mathrm{dsubs}\,\mathrm{mapde}\,\mathrm{separability}\,\mathrm{splitstrip}\,\mathrm{splitsys}\,\mathrm{undeclare}\right]$

When the general solution is found, it is returned directly in equation format

PDE := diff(f(x,y,z),y)+diff(f(x,y,z),x)/x/z=diff(f(x,y,z),z);

$\mathrm{PDE}≔\frac{\partial }{\partial y}f\left(x\,y\,z\right)+\frac{\frac{\partial }{\partial x}f\left(x\,y\,z\right)}{xz}=\frac{\partial }{\partial z}f\left(x\,y\,z\right)$

ans := pdsolve(PDE);

$\mathrm{ans}≔f\left(x\,y\,z\right)=\mathrm{f\_\_1}\left(z{\ⅇ}^{\frac{x^2}{2}}\,z+y\right)$

Answers can be tested using pdetest

pdetest(ans, PDE);

$0$

When the answer obtained is not the most general one, pdsolve returns using the structure of the solution, to allow the user to determine whether the answer is useful or not

PDE := diff(f(x,y,z),y)^2*exp(2*y)+diff(f(x,y,z),x)/cos(x)/z=diff(f(x,y,z),z);

$\mathrm{PDE}≔{\left(\frac{\partial }{\partial y}f\left(x\,y\,z\right)\right)}^2{\ⅇ}^{2y}+\frac{\frac{\partial }{\partial x}f\left(x\,y\,z\right)}{\cos \left(x\right)z}=\frac{\partial }{\partial z}f\left(x\,y\,z\right)$

ans := pdsolve(PDE);

$\mathrm{ans}≔f\left(x\,y\,z\right)=\mathrm{f\_\_1}\left(x\right)+\mathrm{f\_\_2}\left(y\right)+\mathrm{f\_\_3}\left(z\right)\mathbf{where}\left[\left\{{\left(\frac{\ⅆ}{\ⅆy}\mathrm{f\_\_2}\left(y\right)\right)}^2={\ⅇ}^{-2y}{\mathrm{\_c}}_2\,\frac{\ⅆ}{\ⅆx}\mathrm{f\_\_1}\left(x\right)={\mathrm{\_c}}_1\cos \left(x\right)\,\frac{\ⅆ}{\ⅆz}\mathrm{f\_\_3}\left(z\right)=\frac{{\mathrm{\_c}}_1}{z}+{\mathrm{\_c}}_2\right\}\right]$

That is, on the left is the result found for the indeterminate function, and on the right is a list. In this case, the list contains a set of ODEs for the functions _F1, _F2 and _F3, introduced by pdsolve when building the result. In other examples the list may contain, additionally, an indication of any arbitrary functions and/or change of variables introduced during the solving process. To see the resulting expression for the indeterminate function f(x,y,z), it is possible to use the build command:

build(ans);

$f\left(x\,y\,z\right)={\mathrm{\_c}}_1\sin \left(x\right)+\mathrm{c\_\_1}-\sqrt{\frac{{\mathrm{\_c}}_2}{{\left({\ⅇ}^y\right)}^2}}+\mathrm{c\_\_2}+{\mathrm{\_c}}_1\ln \left(z\right)+{\mathrm{\_c}}_{2}z+\mathrm{c\_\_3}$

A suitable change of variables is the most 'powerful' method when the solution cannot be found by other means. These changes or variables can now be performed using dchange. As a blackboard example, consider for instance the reduction of the number of differentiation variables in a given PDE

PDE := 1+F(x,y)^2+y*diff(F(x,y),x)-x*diff(F(x,y),y);

$\mathrm{PDE}≔1+{F\left(x\,y\right)}^2+y\left(\frac{\partial }{\partial x}F\left(x\,y\right)\right)-x\left(\frac{\partial }{\partial y}F\left(x\,y\right)\right)$

The solution to the PDE above is in fact invariant under rotations in the plane, which means that introducing polar coordinates (the natural coordinates for describing rotations) we will obtain the aforementioned reduction

TR := {x=r*cos(phi), y=r*sin(phi)};

$\mathrm{TR}≔\left\{x=r\cos \left(\mathrm{\phi }\right)\,y=r\sin \left(\mathrm{\phi }\right)\right\}$

dchange(TR, PDE, simplify);

${F\left(\mathrm{\phi }\,r\right)}^2+1-\frac{\partial }{\partial \mathrm{\phi }}F\left(\mathrm{\phi }\,r\right)$

The resulting PDE is easily solvable

ans := pdsolve((38));

$\mathrm{ans}≔F\left(\mathrm{\phi }\,r\right)=\tan \left(\mathrm{\phi }+\mathrm{f\_\_1}\left(r\right)\right)$

and the answer to the original problem can be obtained changing variables back

ITR := {r=sqrt(x^2+y^2), phi=arctan(y/x)};

$\mathrm{ITR}≔\left\{\mathrm{\phi }=\arctan \left(\frac{y}{x}\right)\,r=\sqrt{x^2+y^2}\right\}$

dchange(ITR, ans, known=_F1, simplify);

$F\left(x\,y\right)=\tan \left(\arctan \left(\frac{y}{x}\right)+\mathrm{f\_\_1}\left(\sqrt{x^2+y^2}\right)\right)$

pdetest((41),PDE);

$0$

dchange is a general change of variables command and as such it can be used to change variables in procedures directly or in integrals (actually any valid Maple expression; see the related help page).

An extensive set of facilities for working with three-dimensional geometric objects and algorithms is provided in the new geom3d package.

Using the geom3d package, you can manipulate a wide variety of geometric objects, including points, lines, planes, spheres, polyhedra, and other solids.

Use the geom3d package by entering the with command.  You can refer to procedures in the package by their short names.

restart;

with( geom3d ):

It is very easy to create a variety of geometric objects.

tetrahedron( T, point( O, 0, 0, 0 ), 3 );

Warning, a geometry object has been assigned to the protected name O.  Use of protected names for geometry objects is not recommended and may break Maple functionality.

$T$

faces( T );

$\left[\left[\left[\sqrt{3}\,\sqrt{3}\,\sqrt{3}\right]\,\left[\sqrt{3}\,-\sqrt{3}\,-\sqrt{3}\right]\,\left[-\sqrt{3}\,\sqrt{3}\,-\sqrt{3}\right]\right]\,\left[\left[\sqrt{3}\,\sqrt{3}\,\sqrt{3}\right]\,\left[-\sqrt{3}\,-\sqrt{3}\,\sqrt{3}\right]\,\left[\sqrt{3}\,-\sqrt{3}\,-\sqrt{3}\right]\right]\,\left[\left[\sqrt{3}\,\sqrt{3}\,\sqrt{3}\right]\,\left[-\sqrt{3}\,\sqrt{3}\,-\sqrt{3}\right]\,\left[-\sqrt{3}\,-\sqrt{3}\,\sqrt{3}\right]\right]\,\left[\left[\sqrt{3}\,-\sqrt{3}\,-\sqrt{3}\right]\,\left[-\sqrt{3}\,-\sqrt{3}\,\sqrt{3}\right]\,\left[-\sqrt{3}\,\sqrt{3}\,-\sqrt{3}\right]\right]\right]$

area( T );

$24\sqrt{3}$

volume( T );

$8\sqrt{3}$

You can visualize geometric objects using the draw command.

draw( T );

See the list of example worksheets for example worksheets available for this package.

True strings are added to Maple V Release 5.  Previously, names also acted as strings when necessary.

Strings and names are identified with a different syntax:

s := "This is a string";

$s≔''This\; is\; a\; string''$

type( s, 'string' );

$\mathrm{true}$

type( s, 'name' );

$\mathrm{false}$

n := `This is a name`;

$n≔\mathrm{This\; is\; a\; name}$

type( n, 'string' );

$\mathrm{false}$

type( n, 'name' );

$\mathrm{true}$

A fundamental distinction between names and strings is that names may be assigned a value, while strings cannot.

`A name` := 5;

$\mathrm{A\; name}≔5$

"A string" := 5;

Error, invalid left hand side of assignment

Many procedures which formerly took names or strings as parameters, or returned names for use as strings, now will accept strings (and names), and return strings.

save `A name`, "/tmp/junk.m";

printf( "%s: %d\n", "A String of length: ", length( "A String of length: " ) );

A String of length: : 20

The MATLAB® Link allows you to open a connection to the MATLAB® numeric software package, and carry out computations there, returning the results to your current Maple session.

To use this package, you must have a correctly installed, licensed copy of MATLAB® on your computer. The Matlab example worksheet provides further explanation and examples. (Note: you will need MATLAB® to execute this worksheet.)

Example Computation

To establish a connection with MATLAB®, and to make available the Maple commands for interacting with it, use the with command to load the Matlab package.

with( Matlab ):

First, define a four by four Maple matrix.  Use the Maple command below.

m := linalg[ 'randmatrix' ]( 4, 4 );

$m≔\left[\begin{array}{cccc}\mathrm{-7}& 22& \mathrm{-55}& \mathrm{-94}\\ 87& \mathrm{-56}& 0& \mathrm{-62}\\ 97& \mathrm{-73}& \mathrm{-4}& \mathrm{-83}\\ \mathrm{-10}& 62& \mathrm{-82}& 80\end{array}\right]$

To define a MATLAB® variable, use the procedure setvar.

setvar( "m", m );

The MATLAB® variable "m" is defined to have the same value as the Maple variable m. Note that the variable "m" now exists in the current MATLAB® session to which Maple is connected.

Compute the Schur decomposition of this matrix m in MATLAB® by issuing the command

evalM( "r = schur( m )" );

Note the distinction between the evalM command and Maple's matrix evaluator, evalm.

This command sends the MATLAB® command enclosed in quotation marks to the running MATLAB® session to be executed. In this case, a MATLAB® variable "r" is assigned the value of the Schur decomposition of the MATLAB® variable "m".

Now retrieve the value of "r" from MATLAB®, using the getvar command.

s := getvar( "r" );

Finally, to convert this to a Maple matrix, use the command

a := evalm( convert( s, 'array' ) );

Arrays of hardware floating point numbers have been added to Maple V Release 5. Using arrays of hardware floating point numbers (called hfarrays in Maple) can dramatically improve the performance of numerical algorithms.

If you write a procedure that will be evaluated within evalhf, be careful not to introduce any symbolic constructs.

A simple, but nontrivial example of hfarrays is an implementation of the ``forward elimination'' algorithm employed by traditional Gaussian Elimination for square numerical matrices. The main departure from the straightforward description of the algorithm is that we take a little care to choose our pivot in a way that helps to proscribe numerical instability.

macro( forelim = `HFGaussElim/forelim` );

$\mathrm{forelim}$

forelim :=      proc(r::posint, m::{array,hfarray})

    local   i, j, k,        # indices
            max,            # used to choose the pivot row
            t;              # temporary for swapping

    # for each row
    for i from 1 to r do

        max := i;

        # find the pivot row
        # (should be modified for sparse implementation)
        for j from 1 + i to r do
            if abs( m[ j, i ] ) > abs( m[ max, i ] ) then
                max := j;
            fi;
        od;

        # interchange
        for k from i to r do
            # swap
            t := m[ i, k ];
            m[ i, k ] := m[ max, k ];
            m[ max, k ] := t;
        od;

        # do the pivot
        for j from 1 + i to r do
            for k from r to i by -1 do
                m[ j, k ] := m[ j, k ] - m[ i, k ] * m[ j, i ] / m[ i, i ];
            od;
        od;

    od;

    m;
end;

$\mathrm{HFGaussElim/forelim}:=\mathbf{proc}\left(r::\mathrm{posint}\&comma;m::\left\{\mathrm{array}\&comma;\mathrm{hfarray}\right\}\right)\mathbf{local}i\&comma;j\&comma;k\&comma;\max \&comma;t\&semi;\mathbf{for}i\mathbf{to}r\mathbf{do}\max :=i\&semi;\mathbf{for}j\mathbf{from}i\&plus;1\mathbf{to}r\mathbf{do}\mathbf{if}\mathrm{abs}\left(m\&lsqb;\max \&comma;i\&rsqb;\right)<\mathrm{abs}\left(m\&lsqb;j\&comma;i\&rsqb;\right)\mathbf{then}\max :=j\mathbf{end\; if}\mathbf{end\; do}\&semi;\mathbf{for}k\mathbf{from}i\mathbf{to}r\mathbf{do}t:=m\&lsqb;i\&comma;k\&rsqb;\&semi;m\&lsqb;i\&comma;k\&rsqb;:=m\&lsqb;\max \&comma;k\&rsqb;\&semi;m\&lsqb;\max \&comma;k\&rsqb;:=t\mathbf{end\; do}\&semi;\mathbf{for}j\mathbf{from}i\&plus;1\mathbf{to}r\mathbf{do}\mathbf{for}k\mathbf{from}r\mathbf{by}\&minus;1\mathbf{to}i\mathbf{do}m\&lsqb;j\&comma;k\&rsqb;:=m\&lsqb;j\&comma;k\&rsqb;-m\&lsqb;i\&comma;k\&rsqb;\&ast;m\&lsqb;j\&comma;i\&rsqb;\&sol;m\&lsqb;i\&comma;i\&rsqb;\mathbf{end\; do}\mathbf{end\; do}\mathbf{end\; do}\&semi;m\mathbf{end\; proc}$

Given a square matrix as input, an upper triangular matrix, row- equivalent to the input, is produced.

forelim( 4, matrix( 4, 4, [ 1, 2, 3, 4, 2, 3, 4, 1, 3, 4, 1, 2, 4, 1, 2, 3 ] ) );

$\left[\begin{array}{cccc}4& 1& 2& 3\\ 0& \frac{13}{4}& -\frac{1}{2}& -\frac{1}{4}\\ 0& 0& \frac{44}{13}& -\frac{4}{13}\\ 0& 0& 0& \frac{40}{11}\end{array}\right]$

Now we can wrap forelim in a procedure HFGaussElim that checks its arguments and evaluates forelim with the evalhf environment.

HFGaussElim     :=      proc(m::matrix)
    local   rows, cols, i, j, lm;

    rows := linalg[ 'rowdim' ]( m );
    cols := linalg[ 'coldim' ]( m );

    if rows <> cols then
            ERROR( "Must be a square matrix" );
    fi;

    lm := matrix( rows, rows );
    for i from 1 to rows do
            for j from 1 to cols do
                    lm[ i, j ] := m[ i, j ];
            od;
    od;

    evalhf( forelim( rows, var( lm ) ) );

    eval( lm );
end;

$\mathrm{HFGaussElim}:=\mathbf{proc}\left(m::\mathrm{matrix}\right)\mathbf{local}\mathrm{rows}\&comma;\mathrm{cols}\&comma;i\&comma;j\&comma;\mathrm{lm}\&semi;\mathrm{rows}:=\mathrm{linalg}\&lsqb;\&apos;\mathrm{rowdim}\&apos;\&rsqb;\left(m\right)\&semi;\mathrm{cols}:=\mathrm{linalg}\&lsqb;\&apos;\mathrm{coldim}\&apos;\&rsqb;\left(m\right)\&semi;\mathbf{if}\mathrm{rows}<>\mathrm{cols}\mathbf{then}\mathrm{ERROR}\left(''Must\; be\; a\; square\; matrix''\right)\mathbf{end\; if}\&semi;\mathrm{lm}:=\mathrm{matrix}\left(\mathrm{rows}\&comma;\mathrm{rows}\right)\&semi;\mathbf{for}i\mathbf{to}\mathrm{rows}\mathbf{do}\mathbf{for}j\mathbf{to}\mathrm{cols}\mathbf{do}\mathrm{lm}\&lsqb;i\&comma;j\&rsqb;:=m\&lsqb;i\&comma;j\&rsqb;\mathbf{end\; do}\mathbf{end\; do}\&semi;\mathrm{evalhf}\left(\mathrm{`HFGaussElim/forelim`}\left(\mathrm{rows}\&comma;\mathrm{var}\left(\mathrm{lm}\right)\right)\right)\&semi;\mathrm{eval}\left(\mathrm{lm}\right)\mathbf{end\; proc}$

Construct a large random matrix to test the performance of the hfarrays compared to the default floating point Gaussian Elimination used in Maple.  Run both algorithms using the random matrix as input. To force Maple's gausselim procedure to use its own floating point algorithm, we explicitly set one of the matrix entries to a nonintegral value.

m := linalg[ 'randmatrix' ]( 50, 50 ): # get a big matrix

m[ 1, 1 ] := 0.5; # force floating point algorithm

$m_{1,1}≔0.5$

st := time():

linalg[ 'gausselim' ]( m ):

time() - st;

$0.131$

st := time():

HFGaussElim( m ):

time() - st;

$0.031$

The Algebraic Curves package, algcurves, allows you to study (the one-dimensional) algebraic varieties (curves) defined by multivariate polynomials.

You can examine singularities, Puiseaux expansions, compute the genus and j-invariant, and determine an integral basis using this package.

An Example

Consider the algebraic curve defined by the polynomial:

f := x^2 - y^3;

$f≔-y^3+x^2$

If you execute the following plot commands in a worksheet, you can see what the graph of f looks like.

plots['implicitplot']( f, x=-10..10, y=-10..10, numpoints=10000 );

Compute the singularities of f, by using the singularities command in the algcurves package. The entire package can be loaded first using the with command:

with( 'algcurves' );

$\left[\mathrm{AbelMap}\&comma;\mathrm{Siegel}\&comma;\mathrm{Weierstrassform}\&comma;\mathrm{algfun\_series\_sol}\&comma;\mathrm{differentials}\&comma;\mathrm{genus}\&comma;\mathrm{homogeneous}\&comma;\mathrm{homology}\&comma;\mathrm{implicitize}\&comma;\mathrm{integral\_basis}\&comma;\mathrm{intersectcurves}\&comma;\mathrm{is\_hyperelliptic}\&comma;\mathrm{j\_invariant}\&comma;\mathrm{monodromy}\&comma;\mathrm{parametrization}\&comma;\mathrm{periodmatrix}\&comma;\mathrm{plot\_knot}\&comma;\mathrm{plot\_real\_curve}\&comma;\mathrm{puiseux}\&comma;\mathrm{singularities}\right]$

singularities( f, x, y );

$\left\{\left[\left[0\&comma;0\&comma;1\right]\&comma;2\&comma;1\&comma;1\right]\right\}$

A Puiseux expansion of f at $x=0$ can be obtained using the puiseux command in the algcurves package.

puiseux( f, x = 0, y, 3 );

$\left\{x^{\raisebox{1ex}{$2$}\!\left/ \!\raisebox{-1ex}{$3$}\right.}\right\}$

The final $3$ passed to puiseux indicates the truncation order desired in the series expansion.

This curve f is irreducible; not only over the rationals, because

factor( f );

$-y^3+x^2$

but also over any algebraic number field. We can verify this as follows:

evala( AFactor( f ) );

$-y^3+x^2$

The last computation uses the evaluator evala to evaluate the inert procedure call $\mathrm{AFactor}\left(f\right)$. This factors f over the field of complex numbers.

Computing the genus of the curve f is quite simple:

genus( f, x, y );

$0$

Since f is a genus zero curve, we can compute its parametrization in terms of a parameter t.

parametrization( f, x, y, t );

$\left[t^3\&comma;t^2\right]$

Search for singularities (which are provided, below, in homogeneous coordinates) using the singularities command in the algcurves package.

singularities( f, x, y );

$\left\{\left[\left[0\&comma;0\&comma;1\right]\&comma;2\&comma;1\&comma;1\right]\right\}$

Notice the singularity at 0.

Another Example

Consider the following curve of genus $3$:

f := x * y^3 - x^2 * y - x + y^5;

$f≔y^5+x{y}^3-x^{2}y-x$

Display the curve by copying the command below to a worksheet and executing the plot.

plots[ 'implicitplot' ]( f, x = -10..10, y = -10..10 );

The algcurves package can be used to find a parametrization of an algebraic curve. The inverse problem, although it can be easily solved using resultants, will provide for an interesting but simple problem to work out using the new Groebner package.

Consider the parametric curve

restart;

with( Groebner );

$\left[\mathrm{Basis}\&comma;\mathrm{FGLM}\&comma;\mathrm{HilbertDimension}\&comma;\mathrm{HilbertPolynomial}\&comma;\mathrm{HilbertSeries}\&comma;\mathrm{Homogenize}\&comma;\mathrm{InitialForm}\&comma;\mathrm{InterReduce}\&comma;\mathrm{IsBasis}\&comma;\mathrm{IsProper}\&comma;\mathrm{IsZeroDimensional}\&comma;\mathrm{LeadingCoefficient}\&comma;\mathrm{LeadingMonomial}\&comma;\mathrm{LeadingTerm}\&comma;\mathrm{MatrixOrder}\&comma;\mathrm{MaximalIndependentSet}\&comma;\mathrm{MonomialOrder}\&comma;\mathrm{MultiplicationMatrix}\&comma;\mathrm{MultivariateCyclicVector}\&comma;\mathrm{NormalForm}\&comma;\mathrm{NormalSet}\&comma;\mathrm{RationalUnivariateRepresentation}\&comma;\mathrm{Reduce}\&comma;\mathrm{RememberBasis}\&comma;\mathrm{SPolynomial}\&comma;\mathrm{Solve}\&comma;\mathrm{SuggestVariableOrder}\&comma;\mathrm{Support}\&comma;\mathrm{TestOrder}\&comma;\mathrm{ToricIdealBasis}\&comma;\mathrm{TrailingTerm}\&comma;\mathrm{UnivariatePolynomial}\&comma;\mathrm{Walk}\&comma;\mathrm{WeightedDegree}\right]$

sigma := [ t^2, t^3 ];

$\mathrm{\sigma }≔\left[t^2\&comma;t^3\right]$

Determine a polynomial in the variables x and y having this parametrization.

vars := [ 'x', 'y' ];

$\mathrm{vars}≔\left[x\&comma;y\right]$

nvars := nops( vars );

$\mathrm{nvars}≔2$

Form the set of polynomial equations to solve.

eqns := { seq( vars[ i ] - sigma[ i ], i = 1 .. nvars ) };

$\mathrm{eqns}≔\left\{-t^2+x\&comma;-t^3+y\right\}$

Next, compute a Groebner basis for elimination of the variables in t. The ordering of the variables in this command is crucial.

GB := gbasis( eqns, lexdeg( [ 't' ], vars ) );

Warning, Groebner[gbasis] is deprecated. Please, use Groebner[Basis].

$\mathrm{GB}≔\left[x^3-y^2\&comma;ty-x^2\&comma;tx-y\&comma;t^2-x\right]$

GB := remove( has, GB, t );

$\mathrm{GB}≔\left[x^3-y^2\right]$

Using this method, the original curve described by the polynomial $x^3-y^2$ is recovered.