Killing tensors, Killing-Yano tensors, Killing spinors, covariantly constant tensors, and recurrent tensors are examples of tensors which are defined as solutions to certain over-determined systems of linear partial differential equations. The DifferentialGeometry package generates these PDE systems; these equations are solved by pdsolve, and the solutions are re-expressed as tensor fields of the appropriate type.

We define a metric $g$ on a manifold $M$ and calculate the covariantly constant 1-forms, the rank 2 Killing tensors, and the rank 2 Killing-Yano tensors.

with(DifferentialGeometry): with(Tensor):

DGsetup([x, y, z], M);

$\mathrm{frame\; name:\; M}$

g := evalDG(dx &t dx + dy &t dy + x^3*dz &t dz);

$g≔\mathrm{dx}\mathrm{dx}+\mathrm{dy}\mathrm{dy}+x^3\mathrm{dz}\mathrm{dz}$

CurvatureTensor(g);

$-\frac{3x\mathrm{D\_x}}{4}\mathrm{dz}\mathrm{dx}\mathrm{dz}+\frac{3x\mathrm{D\_x}}{4}\mathrm{dz}\mathrm{dz}\mathrm{dx}+\frac{3\mathrm{D\_z}}{4x^2}\mathrm{dx}\mathrm{dx}\mathrm{dz}-\frac{3\mathrm{D\_z}}{4x^2}\mathrm{dx}\mathrm{dz}\mathrm{dx}$

CovariantlyConstantTensors(g, [dx, dy, dz]);

$\left[\mathrm{dy}\right]$

KillingTensors(g, 2);

$\left[\mathrm{dy}\mathrm{dy}\,y\mathrm{dx}\mathrm{dx}-\frac{x\mathrm{dx}}{2}\mathrm{dy}-\frac{x\mathrm{dy}}{2}\mathrm{dx}+\frac{x^{3}z\mathrm{dy}}{4}\mathrm{dz}+\frac{x^{3}z\mathrm{dz}}{4}\mathrm{dy}+x^{3}y\mathrm{dz}\mathrm{dz}\,\mathrm{dx}\mathrm{dx}+x^3\mathrm{dz}\mathrm{dz}\,\frac{x^3\mathrm{dy}}{2}\mathrm{dz}+\frac{x^3\mathrm{dz}}{2}\mathrm{dy}\,x^6\mathrm{dz}\mathrm{dz}\right]$

KillingYanoTensors(g, 2);

$\left[x^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{dx}\bigwedge \mathrm{dz}\right]$

The principal null directions of a space-time are preferred directions determined by rather complicated nonlinear algebraic equations formed from the Weyl tensor of the space-time metric $g$.

The new command PrincipalNullDirections uses the two-component spinor formalism of the DifferentialGeometry package to calculate principal null direction via the new command AdaptedSpinorDyad.

with(DifferentialGeometry): with(Tensor):

DGsetup([t, x, y, z], M);

$\mathrm{frame\; name:\; M}$

Define a metric and a null tetrad for the metric.

g := evalDG(dx &t dx + dy &t dy + 1/2*exp(2*x)*dz &t dz - 1/2*(dt + exp(x)*dz) &s (dt + exp(x)*dz));

$g≔-\frac{\mathrm{dt}}{2}\mathrm{dt}-\frac{{\ⅇ}^x\mathrm{dt}}{2}\mathrm{dz}+\mathrm{dx}\mathrm{dx}+\mathrm{dy}\mathrm{dy}-\frac{{\ⅇ}^x\mathrm{dz}}{2}\mathrm{dt}$

NT := evalDG([-(1/2)*sqrt(2)*(sqrt(2)-1)*D_t+exp(-x)*D_z, (1/2)*sqrt(2)*(1+sqrt(2))*D_t-exp(-x)*D_z, (1/2)*sqrt(2)*D_x+(1/2*I)*sqrt(2)*D_y, (1/2)*sqrt(2)*D_x-(1/2*I)*sqrt(2)*D_y]);

$\mathrm{NT}≔\left[-\frac{\sqrt{2}\left(\sqrt{2}-1\right)\mathrm{D\_t}}{2}+{\ⅇ}^{-x}\mathrm{D\_z}\,\frac{\sqrt{2}\left(1+\sqrt{2}\right)\mathrm{D\_t}}{2}-{\ⅇ}^{-x}\mathrm{D\_z}\,\frac{\sqrt{2}\mathrm{D\_x}}{2}+\frac{\mathrm{I}}{2}\sqrt{2}\mathrm{D\_y}\,\frac{\sqrt{2}\mathrm{D\_x}}{2}-\frac{\mathrm{I}}{2}\sqrt{2}\mathrm{D\_y}\right]$

Find the Petrov type of the metric -- this is needed in order to determine the number of principal null directions and the algorithm which will be used to calculate them.

PetrovType(NT);

$''D''$

For type "D" space-times there are always two principal null directions.

PND := PrincipalNullDirections(NT, "D");

$\mathrm{PND}≔\left[\sqrt{2}\mathrm{D\_t}-\mathrm{I}\sqrt{2}\mathrm{RootOf}\left({\mathrm{\_Z}}^2+1\right)\mathrm{D\_y}\,\frac{\sqrt{2}\mathrm{D\_t}}{4}+\frac{\mathrm{I}}{4}\sqrt{2}\mathrm{RootOf}\left({\mathrm{\_Z}}^2+1\right)\mathrm{D\_y}\right]$

allvalues(PND)[1];

$\left[\sqrt{2}\mathrm{D\_t}+\sqrt{2}\mathrm{D\_y}\,\frac{\sqrt{2}\mathrm{D\_t}}{4}-\frac{\sqrt{2}\mathrm{D\_y}}{4}\right]$

For four-dimensional space-times, the Petrov type is a fundamental invariant which provides important information about the geometric properties of the space. The possible Petrov types are ["I", "II", "III", "D", "N", "O"]. If the metric depends upon parameters (either constants or functions), then the Petrov type can change for exceptional values of these parameters.

New keyword arguments for the command PetrovType make it now possible to identity these exceptional values.

with(DifferentialGeometry): with(Tensor):

DGsetup([u, v, y, z], M);

$\mathrm{frame\; name:\; M}$

We define a metric depending upon 2 parameters $\left\{p\,q\right\}$.

g := evalDG(1/y^(2)*(dy &t dy   - du &s dv ) + y^(2*p)*dz &t dz  +  y^(2*q) *dv &t dv);

$g≔-\frac{\mathrm{du}}{2y^2}\mathrm{dv}-\frac{\mathrm{dv}}{2y^2}\mathrm{du}+y^{2q}\mathrm{dv}\mathrm{dv}+\frac{\mathrm{dy}}{y^2}\mathrm{dy}+y^{2p}\mathrm{dz}\mathrm{dz}$

Here is a null tetrad we shall use to calculate the Petrov type of the metric g.

NT := evalDG([y*D_u, (1/2)*y^(3+2*q)*D_u + y*D_v, (1/2)*sqrt(2)*y*D_y + (1/2*I)*sqrt(2)*y^(-p)*D_z, (1/2)*sqrt(2)*y*D_y - (1/2*I)*sqrt(2)*y^(-p)*D_z]);

$\mathrm{NT}≔\left[y\mathrm{D\_u}\,\frac{y^{3+2q}\mathrm{D\_u}}{2}+y\mathrm{D\_v}\,\frac{\sqrt{2}y\mathrm{D\_y}}{2}+\frac{\mathrm{I}}{2}\sqrt{2}{y}^{-p}\mathrm{D\_z}\,\frac{\sqrt{2}y\mathrm{D\_y}}{2}-\frac{\mathrm{I}}{2}\sqrt{2}{y}^{-p}\mathrm{D\_z}\right]$

We find that this metric is of Petrov type "I" for generic values of the parameters $\left\{p\,q\right\}$. There are exceptional values leading to space-times of Petrov type "N", "D", "O".

PetrovType(NT, parameters = [p, q]);

$table\left(\left[''N''=\left[\left\{p=\mathrm{-1}\right\}\,\left\{p=0\right\}\,\left\{p=\mathrm{-1}\,q=q\right\}\,\left\{p=0\,q=q\right\}\right]\,''D''=\left[\left\{p=2q\,q=q\right\}\right]\,''I''=\left[\right]\,''III''=\left[\right]\,''O''=\left[\left\{p=\mathrm{-1}\,q=-\frac{1}{2}\right\}\,\left\{p=0\,q=0\right\}\right]\,''II''=''generic''\right]\right)$

With the keyword argument auxiliaryequations, additional constraints can be imposed upon the parameters.

PetrovType(NT, auxiliaryequations = [p^2 + q^2 = 4], parameters = [p, q]);

$table\left(\left[''N''=\left[\left\{p=\mathrm{-1}\,q=\sqrt{3}\right\}\,\left\{p=\mathrm{-1}\,q=-\sqrt{3}\right\}\,\left\{p=\mathrm{-1}\,q=\mathrm{RootOf}\left({\mathrm{\_Z}}^2-3\right)\right\}\,\left\{p=0\,q=\mathrm{-2}\right\}\,\left\{p=0\,q=2\right\}\right]\,''D''=\left[\left\{p=-\frac{4\sqrt{5}}{5}\,q=-\frac{2\sqrt{5}}{5}\right\}\,\left\{p=\frac{4\sqrt{5}}{5}\,q=\frac{2\sqrt{5}}{5}\right\}\right]\,''I''=\left[\right]\,''III''=\left[\right]\,''O''=\left[\right]\,''II''=''generic''\right]\right)$

We first define a simple class of metrics in two dimensions, depending upon a parameter $k$.

DGsetup([x, y], M);

$\mathrm{frame\; name:\; M}$

g := evalDG(y^k*( dx &t dx + dy &t dy));

$g≔y^k\mathrm{dx}\mathrm{dx}+y^k\mathrm{dy}\mathrm{dy}$

When $k=0$, this metric is the standard flat metric in the plane and therefore admits a three-dimensional group of isometries -- with infinitesimal generators or Killing vectors $\left\{{\partial }_x\,{\partial }_y\,{y\left(\partial \right)}_x-{x\left(\partial \right)}_y\right\}$.

When $k=2$, this becomes the well-known metric for the Poincare half-plane and again there are 3 Killing vectors.

For other values of $k$, there is an obvious Killing vector ${\partial }_x$.

We can use the KillingVectors command, with the keyword argument parameter, to calculate the Killing vectors for this metric and to determine both the generic and exceptional cases. We see that the well-known cases we just mentioned are the only exceptional ones.

KillingVectors(g, parameters = {k});

$\left[-y\mathrm{D\_x}+x\mathrm{D\_y}\,\mathrm{D\_y}\,\mathrm{D\_x}\right],\left[\left(\frac{x^2}{2}-\frac{y^2}{2}\right)\mathrm{D\_x}+yx\mathrm{D\_y}\,x\mathrm{D\_x}+y\mathrm{D\_y}\,\mathrm{D\_x}\right],\left[\mathrm{D\_x}\right],\left[\left\{k=0\right\}\,\left\{k=\mathrm{-2}\right\}\,\left\{k=k\right\}\right]$

The command MinimalSubalgebras has been extended to work with matrices. Given a list of matrices $A$, this command with calculate the smallest list of matrices which contains $A$ and which is closed under the operation of matrix commutation.

with(DifferentialGeometry): with(LieAlgebras):

A := [Matrix([[1, 0, 0], [0, 1, 0], [1, 0, 0]]), Matrix([[0, 1, 0], [0, 1, 1], [0, 1, 0]])];

$A≔\left[\left[\begin{array}{ccc}1& 0& 0\\ 0& 1& 0\\ 1& 0& 0\end{array}\right]\,\left[\begin{array}{ccc}0& 1& 0\\ 0& 1& 1\\ 0& 1& 0\end{array}\right]\right]$

B := MinimalSubalgebra(A);

$B≔\left[\left[\begin{array}{ccc}1& 0& 0\\ 0& 1& 0\\ 1& 0& 0\end{array}\right]\,\left[\begin{array}{ccc}0& 1& 0\\ 0& 1& 1\\ 0& 1& 0\end{array}\right]\,\left[\begin{array}{ccc}0& 0& 0\\ \mathrm{-1}& 0& 1\\ 0& 0& 0\end{array}\right]\,\left[\begin{array}{ccc}\mathrm{-1}& 0& 1\\ \mathrm{-1}& 0& 1\\ \mathrm{-1}& 0& 1\end{array}\right]\right]$

Given a matrix algebra, as defined by a list of matrices $A$ which are closed under matrix commutation, the corresponding matrix group can be calculated by taking the matrix exponential of a general linear combination of the elements of $A$. The result is usually rather complicated and not so useful for subsequently analysis. The command MatrixGroup will use some simple heuristics to simplify the expression for the matrix group.

with(DifferentialGeometry): with(LieAlgebras): with(Library): with(GroupActions):

A1 := Matrix([[0, 0, 1, 0], [0, 0, 0, -1], [0, 0, 0, 0], [0, 0, 0, 0]]):

A2 := Matrix([[0, 0, 0, 1], [0, 0, 1, 0], [0, 0, 0, 0], [0, 0, 0, 0]]):

A3 := Matrix([[-1, 0, 0, 0], [0, -1, 0, 0], [0, 0, 0, 0], [0, 0, 0, 0]]):

A4 := Matrix([[0, -1, 0, 0], [1, 0, 0, 0], [0, 0, 0, 0], [0, 0, 0, 0]]):

A := [A1, A2, A3, A4];

$A≔\left[\left[\begin{array}{cccc}0& 0& 1& 0\\ 0& 0& 0& \mathrm{-1}\\ 0& 0& 0& 0\\ 0& 0& 0& 0\end{array}\right]\,\left[\begin{array}{cccc}0& 0& 0& 1\\ 0& 0& 1& 0\\ 0& 0& 0& 0\\ 0& 0& 0& 0\end{array}\right]\,\left[\begin{array}{cccc}\mathrm{-1}& 0& 0& 0\\ 0& \mathrm{-1}& 0& 0\\ 0& 0& 0& 0\\ 0& 0& 0& 0\end{array}\right]\,\left[\begin{array}{cccc}0& \mathrm{-1}& 0& 0\\ 1& 0& 0& 0\\ 0& 0& 0& 0\\ 0& 0& 0& 0\end{array}\right]\right]$

B, Id := MatrixGroup(A, [u, v, x, y]);

$B,\mathrm{Id}≔\left[\begin{array}{cccc}\frac{\cos \left(u\right)}{v}& -\frac{\sin \left(u\right)}{v}& y& x\\ \frac{\sin \left(u\right)}{v}& \frac{\cos \left(u\right)}{v}& x& -y\\ 0& 0& 1& 0\\ 0& 0& 0& 1\end{array}\right],\left[u=0\,v=1\,x=0\,y=0\right]$

The 4-parameter family of matrices $B$ is closed under matrix multiplication and matrix inversions. The value of the parameters which define the identity is also given.

The DifferentialGeometry package uses a Maple module to represent a general Lie group. The exports of the module are LeftMultiplication, RightMultiplication, Inverse, and Identity. These provide the basic operations for performing computations with Lie groups.

The command LieGroup uses various scenarios construct this Maple module. For Maple 15, new calling sequences for the LieGroup command has been added to include other common situations. In this example, we consider a 5 parameter group of affine transformations in the plane and use the LieGroup command to construct the abstract Lie group defined by this transformation group.

with(DifferentialGeometry): with(GroupActions):

DGsetup([x, y], M);

$\mathrm{frame\; name:\; M}$

DGsetup([a, b, c, d, e], G);

$\mathrm{frame\; name:\; G}$

T := Transformation(M, M, [x = a*x + b*y +c, y = d*y + e]);

$T≔\left[x=ax+by+c\,y=dy+e\right]$

LG := LieGroup(T, G);

$\mathrm{LG}:=\mathbf{module}\left(\right)\mathbf{export}\mathrm{Frame}\,\mathrm{Identity}\,\mathrm{LeftMultiplication}\,\mathrm{RightMultiplication}\,\mathrm{Inverse}\;\mathbf{end\; module}$

LG:-LeftMultiplication([alpha, beta, gamma, delta, epsilon]);

$\left[a=\mathrm{\alpha }a\,b=\mathrm{\alpha }b+\mathrm{\beta }d\,c=\mathrm{\alpha }c+\mathrm{\beta }e+\mathrm{\gamma }\,d=\mathrm{\delta }d\,e=\mathrm{\delta }e+\mathrm{\epsilon }\right]$

The functionality of the command InvariantGeometricObjectFields has been extended to an algebraic setting to allow for the calculation of invariant tensors on Lie algebras.

In this example, we shall create a 4-dimensional Lie algebra and calculate the symmetric rank 2 tensors on this algebra which are invariant with respect to a one-dimensional subalgebra.

with(DifferentialGeometry): with(LieAlgebras): with(GroupActions): with(Tensor):

We use an array of structure constants to initialize our Lie algebra.

C := Array(1..4, 1..4, 1..4, {(1,2,1) = -1, (2,1,1) = 1, (1,3,2)  = -1, (1,2,3) =1, (2,3,3) = -1}):

L := LieAlgebraData(C, Alg);

$L≔\left[\left[\mathrm{e1}\,\mathrm{e2}\right]=-\mathrm{e1}+\mathrm{e3}\,\left[\mathrm{e1}\,\mathrm{e3}\right]=-\mathrm{e2}\,\left[\mathrm{e2}\,\mathrm{e3}\right]=-\mathrm{e3}\right]$

DGsetup(L):

We find the most general rank 2, contravariant, symmetric tensor on the Lie algebra involving the vectors $\left[\mathrm{e2}\,\mathrm{e3}\,\mathrm{e4}\right]$ and invariant with respect to $\left[\mathrm{e1}\right]$.

Q := GenerateSymmetricTensors([e2, e3, e4],2);

$Q≔\left[\mathrm{e2}\mathrm{e2}\,\frac{\mathrm{e2}}{2}\mathrm{e3}+\frac{\mathrm{e3}}{2}\mathrm{e2}\,\frac{\mathrm{e2}}{2}\mathrm{e4}+\frac{\mathrm{e4}}{2}\mathrm{e2}\,\mathrm{e3}\mathrm{e3}\,\frac{\mathrm{e3}}{2}\mathrm{e4}+\frac{\mathrm{e4}}{2}\mathrm{e3}\,\mathrm{e4}\mathrm{e4}\right]$

InvariantGeometricObjectFields([e1], Q, output = "list");

$\left[\mathrm{e4}\mathrm{e4}\right]$

We find the most general rank 2, covariant symmetric tensor on the Lie algebra involving the dual vectors (or 1-forms) $\left[\mathrm{\θ2}\,\mathrm{\θ3}\,\mathrm{\θ4}\right]$ and invariant with respect to $\left[\mathrm{e1}\right]$.

Q := GenerateSymmetricTensors([theta2, theta3, theta4], 2);

$Q≔\left[\mathrm{\θ2}\mathrm{\θ2}\,\frac{\mathrm{\θ2}}{2}\mathrm{\θ3}+\frac{\mathrm{\θ3}}{2}\mathrm{\θ2}\,\frac{\mathrm{\θ2}}{2}\mathrm{\θ4}+\frac{\mathrm{\θ4}}{2}\mathrm{\θ2}\,\mathrm{\θ3}\mathrm{\θ3}\,\frac{\mathrm{\θ3}}{2}\mathrm{\θ4}+\frac{\mathrm{\θ4}}{2}\mathrm{\θ3}\,\mathrm{\θ4}\mathrm{\θ4}\right]$

InvariantGeometricObjectFields([e1], Q, output = "list");

$\left[\mathrm{\θ2}\mathrm{\θ2}+\mathrm{\θ3}\mathrm{\θ3}\,\mathrm{\θ4}\mathrm{\θ4}\right]$

With the new database of solutions to the Einstein equations it is now possible to use the Retrieve command to automatically load into a worksheet known solutions, taken from the general relativity literature.

with(DifferentialGeometry): with(Library):

DGsetup([t, x, y, z], M);

$\mathrm{frame\; name:\; M}$

Retrieve("Stephani", 1, [12, 14, 1], manifoldname = M, output = ["Fields"]);

$\left[-\frac{{\ⅇ}^x\cos \left(\sqrt{3}x\right)\mathrm{dt}}{{\mathrm{\_k}}^2}\mathrm{dt}-\frac{{\ⅇ}^x\sin \left(\sqrt{3}x\right)\mathrm{dt}}{{\mathrm{\_k}}^2}\mathrm{dz}+\frac{\mathrm{dx}}{{\mathrm{\_k}}^2}\mathrm{dx}+\frac{{\ⅇ}^{-2x}\mathrm{dy}}{{\mathrm{\_k}}^2}\mathrm{dy}-\frac{{\ⅇ}^x\sin \left(\sqrt{3}x\right)\mathrm{dz}}{{\mathrm{\_k}}^2}\mathrm{dt}+\frac{{\ⅇ}^x\cos \left(\sqrt{3}x\right)\mathrm{dz}}{{\mathrm{\_k}}^2}\mathrm{dz}\right]$