If a module has an export named ModuleApply, the module name can be used as if it were a procedure name.  Calling M(args) invokes M:-ModuleApply(args).

Maple's module data structure is close to the "class" concept in object oriented programming.  Due to the dynamic nature of Maple, modules can also be used to represent "objects".  One major difference between classes and objects are constructors.  Constructors can be nicely emulated using generated modules. ModuleApply provides the ability to treat a module as a function and make it "apply'able".

m := module() export ModuleApply;
    ModuleApply := proc()
        print("m called with args: ", [args]);
    end proc;
end module;

MyEvalf := proc(f)
    if type(f,function) and type(op(0,f),`module`(Evalf)) then
        op(0,f):-Evalf(op(f));
    else
        error "cannot evaluate %1", f;
    end if;
end proc;

Sine := module() export ModuleApply, Evalf;
    ModuleApply := proc(x)
        if type(x,float) then
            sin(x);
        else
            'Sine'(x);
        end if;
    end proc;
    Evalf := proc(x)
        `evalf/sin`(x);
    end proc;
end module;