初期条件のセットまたはリスト (下記参照)、1 階微分方程式系または単独の高階微分方程式系を指定すると、DEplot は数値解法を使用して解曲線をプロットします。

注意 : これは、問題の初期条件を標準的な形式、つまり、同一点における関数値および微分方程式の階数より 1 少ない値までのすべての導関数を指定しなければならないことを意味しています。

2 つの 1 階微分方程式による系が自律系として求められるように指定した場合、この系によって方向場プロットが生成されます。また、単独 1 階微分方程式では、方向場 (常に 2 つの 1 階自律方程式の系にマッピング可能) が生成されます。微分以外のすべての項と係数に独立変数が含まれていない場合、その系は自律系として計算されます。詳細は DEtools[autonomous] を参照してください。これらの基準を満たさない系の場合、方向場は生成されません (このような場合、解曲線のみ生成可能です)。指定できる独立変数は 1 つのみです。

デフォルトの積分手法は method=rkf45 です。その他の手法はオプションの方程式で指定できます。数値解法を使用してプロットが生成されるため、使用する数値解法の特性に出力が影響されることに注意してください。特に、漸近線を処理する場合に通常でない出力となることがあります。

表示される方向場は、矢印のグリッド、またはランダムに生成された矢印の集合で構成されます。いずれの場合も解曲線に接線方向の矢印です。各グリッド点で、矢印の中心は 、傾きは  です。この傾きは / により計算されます。この式の 2 つの微分は DEplot の最初の引数で指定します。曲線矢印 (curves および comet) では、追加データとして方向場の曲率が必要です。これは傾き  の方向にε移動した  の計算と、傾きの逆方向にε移動した  の計算から求められます。このデータで点の微小な方向場の線を描画し、これを使用して曲線矢印が描画されます。

scene オプションで指定していない限り、デフォルトで 2 つの従属変数がプロットされます。

deqns パラメータをプロシージャとして指定できますが、dsolve/numeric での指定と一致している必要があります。また、初期条件の前に number オプションを指定する必要があります。この場合、deqns は以下の形式でなければなりません。

ここで、N は 1 階方程式の数を表し、ivar は独立変数、Y は長さ N のベクトル、YP は (同値な 1 階の系に対する) プロシージャによって更新される導関数の長さ N のベクトルです。1 階方程式の計算に関する詳細は、DEtools[convertsys] を参照してください。N は 4 番目のパラメータ number で指定します。

inits パラメータは次のように指定する必要があります。

上記の例のように、リストの代わりに集合を使用できます。また、

リストまたはリストの集合の場合、各サブリストが初期条件の 1 つのグループを指定します。

xrange および yrange パラメータは次のように指定する必要があります。

デフォルトでは、解曲線に沿った積分は指定した範囲を 1 メッシュ超えた後の点で止まります。これは obsrange オプションで変更できます。

その他の例題については、deplot を参照してください。

DEplot には、対話型の DEplot アシスタントからもアクセスできます。詳細は DEplot[interactive] を参照してください。

オプションの方程式 eqns では以下のほか、plot および dsolve/numeric オプションの一部を使用できます。

animatecurves = true または false (デフォルト = false)

animatecurves は、指定した値から時間に対して展開する解曲線のアニメーションを作成します。アニメーションフレームのデフォルト値は 25 です。この値は numframes オプションで変更できます。dsolve/numeric を使用して、指定したすべての初期値について、異なった時間における解曲線が計算されます。numpoints を指定し、かつ区間数 () をフレーム数 () で割り切れない場合は、警告が表示され、numpoints が  に修正されます。

animatefield = true または false (デフォルト = false)

animatefield は、時間に基づく方向場のアニメーション (つまり、方向場の矢印が解の時間経過とともに移動) を作成します。アニメーションフレームのデフォルト値は 25 です。この値は numframes オプションで変更できます。それぞれの矢印の軌跡を計算するために dsolve/numeric/rkf45 が使用されます。

animate = true または false (デフォルト = false)

animate は、 animatefield (使用できる場合)と animatecurves (使用できる場合) の両方を指定するためのショートカットです。

arrows = arrowtype

arrowtype には、'small'、'smalltwo'、'medium'、'mediumfill'、'large'、'curve', 'comet'、'line'、または 'none' のいずれかを使用できます。

arrowtype は方向場で使用される矢印の種類を指定します。方向場を使用できる場合のデフォルトは 'small' です。arrowtype に 'none' を指定すると、方向場の計算と表示が抑制されます。

color、colour = arrowcolor

arrowcolor は、いろいろな形式で指定できます。

plot/color 名;

COLOR('HUE', realcons);

COLOR('RGB', realcons, realcons, realcons);

リテラル 'magnitude';

magnitude[plot/color name, plot/color name];

2 変数の式;

2 変数のプロシージャ;

2 変数の式の 3 要素リスト;

2 変数のプロシージャの 3 要素リスト

ケース 4) では、矢印の色がフィールドの大きさによって決まります。最も小さい値は青、最も大きい値は赤になります。ケース 5) はケース 4) と同じですが、最大値と最小値の色を大きさのインデックスとして指定します (たとえば、magnitude は、magnitude[blue,red] に相当します)。ケース 6) と 7) では、平面上の矢印の座標が式またはプロシージャに渡されます。結果の値は範囲 [0,1] で正規化され 'HUE' 値として使用されます。ケース 8) と 9) では、結果の値が [0,1] で正規化され、RGB 値として使用されます。ケース 6) と 8) の場合は、プロットされた変数の式を指定する必要があることに注意してください。この色処理の形式は方向場を識別する機能で役に立ちます。

矢印のデフォルト色は赤です。

dirfield = [posint,posint]、posint、または [[float,float],[float,float],...]

[posint,posint] を使用すると、矢印を配置するグリッドが指定されます。これは非推奨の dirgrid オプションと同じです。posint を使用すると、方向場に使用される、ランダムに配置された矢印の数が指定されます。[[float,float],[float,float],...] を使用すると、矢印が描画される点を各サブリストが表します。

dirgrid = [posint, posint]

dirgrid オプションは下位互換性のために維持されています。このオプションは dirfield = [posint, posint] オプションに相当します。

iterations = posint

iterations は、格納する点の数は一定にしたままでステップサイズを減らす方法を指定します。たとえば、stepsize=0.05 および iterations=5 を指定すると、内部ではステップサイズ  を使用した計算が行われますが、結果は 5 つおきにしか格納されません。このオプションは numpoints に置き換わりました。また、classical 以外の手法では無視されます。

linecolor = line_info

line_info は次の 5 つの形式のいずれかで指定できます。

plot/color 名;

COLOR('HUE', realcons);

COLOR('RGB', realcons, realcons, realcons);

独立変数の式

独立変数のプロシージャ

ケース 4) と 5) では、独立変数の値が式またはプロシージャに渡されます。結果の値は [0,1] で正規化され、'HUE' 値として適用されます。この機能は、独立変数による解曲線の変化を表示する際に役に立ちます。

また、1) ～ 5) をリストとして組み合わせることもできます。この場合、解曲線ごとに 1 つの要素が考慮されます。各リスト要素が対応する解曲線に適用されます。

線のデフォルト色は黄色です。

number = posint

number は、dproc のプロシージャ形式の 1 階系の方程式数を指定します (上記の「使い方」を参照)。

numframes = posint

numframes は、animate、animatefield、または animatecurves オプションを使用したアニメーションで使用されるフレーム数を指定します。

numpoints = posint

numpoints は、指定した時間範囲で曲線をプロットするための点の数を指定します。デフォルトの点の数は 49 です。アニメーションの場合、 は  の整数倍でなければなりません。

numsteps = posint

numsteps を使用すると、stepsize パラメータをより便利な方法で指定することができます。trange=a..b の場合、numsteps=n を指定するとステップサイズ  で計算が行われます。このオプションは numpoints とは無関係です。

注意 : このオプションは classical 固定ステップサイズ法にのみ適用されます。この方法はデフォルトではありません。

obsrange = boolean

obsrange は、解曲線が指定した範囲を超えたら積分器を停止するかどうかを指定します。また、完全に表示領域外にある矢印を削除するかどうかも指定します (矢印ベースのアニメーションの場合)。この指定は、漸近的な挙動を持つ関数をプロットするときに有用です。デフォルトは true です。

scene = [name, name]

scene は表示するプロットの座標軸を指定します。たとえば、scene=[x, y] を指定すると、t を隠して x 対 y (x は横軸) のプロットを表示します。一方、scene=[t, y] は t 対 y を明示的に t を使用してプロットします。このオプションを使用して、変数をプロットする順序を変更することもできます。vars を集合として指定した場合、デフォルトの順序はありません。vars をリストとして指定した場合、指定した順序が使用されます。

size = float または magnitude

size=magnitude を指定した場合、矢印のサイズは方向場の大きさに比例します。size を正の浮動小数点として指定した場合、方向場のすべての矢印のサイズがこの値に変更されます。デフォルト値は size=1.0 です。

stepsize = realcons

stepsize は、classical 手法を使用して曲線を計算する場合に dsolve で使用されるステップサイズを指定します。trange=a..b の場合、デフォルト値は  です。

注意 : 解曲線は thickness のデフォルト値  でプロットされますが、thickness プロットオプションを使用して変更することができます。

その他にも、thickness オプションなど、指定可能なオプションの方程式が多数あります。詳細は、plot/options および dsolve/numeric の各ヘルプページを参照してください。

with(DEtools):

NLC := diff(y(t),t) = k*(Am-y(t)); Am := 20; k := 0.1;

ivs := [y(0)=10,y(0)=30,y(0)=50];

DEplot( NLC, y(t), t=0..20, ivs );

DEplot(NLC,y(t),t=0..40,y=0..60,ivs,arrows=medium,linecolor=black);

deS := diff(x(t),t)=-0.5*x(t)*y(t);

deI := diff(y(t),t)=+0.5*x(t)*y(t)-0.15*y(t);

DEplot( [deS,deI], [x(t),y(t)], t=0..40, x=0..1, y=0..0.6,
  [[x(0)=0.99,y(0)=0.01]], arrows=medium);

DEplot( [deS,deI], [x(t),y(t)], t=0..40, x=0..1, y=0..0.6,
  [[x(0)=0.99,y(0)=0.01]], arrows=medium, animatecurves=true);

de := diff(x(t),t,t) = -x(t)-1/2*diff(x(t),t);

DEplot( de, x(t), t=0..15, x=-1..1, [[x(0)=1,D(x)(0)=0]] );

sys := {diff(x(t),t) = y(t), diff(y(t),t) = -x(t)-1/2*y(t)};

DEplot(sys,[x(t),y(t)],t=0..15,[[x(0)=1,y(0)=0]]);

DEplot(sys,[x(t),y(t)],t=0..15,[[x(0)=1,y(0)=0]],scene=[t,x(t)]);

DEplot(sys,[x(t),y(t)],t=0..15,[[x(0)=1,y(0)=0]],x=-1..1,y=-1..1,
        numpoints=200, linecolor=black, axes=boxed);

F1 := proc(N,x,Y,YP)                  # First order system
    YP[1] := Y[2];
    YP[2] := -Y[1]-1/2*Y[2];
end proc;

DEplot(F1, [x(t),y(t)], t=0..15, number=2, [[y(0)=1,y(0)=0]],
    x=-1..1,y=-1..1,numpoints=200,linecolor=black,axes=boxed);

LVS := [diff(x(t),t)=x(t)*(1-y(t)),diff(y(t),t)=.3*y(t)*(x(t)-1)];

DEplot( LVS, [x(t),y(t)], t=0..10, x=-1..2, y=-1..2, arrows=large,
title=`Lotka-Volterra model`,color=magnitude);

DEplot( LVS, [x(t),y(t)], t=0..10, x=0..3, y=0..2, arrows=comet,
  [[x(0)=1,y(0)=0.5]],title=`Lotka-Volterra model`,dirfield=500);

DEplot( LVS, [x(t),y(t)], t=0..12, x=0..3, y=0..2, arrows=comet,
  [[x(0)=1,y(0)=0.5]],animatecurves=true,dirfield=300);

DEplot( LVS, [x(t),y(t)], t=0..12, x=0..3, y=0..2, arrows=comet,
  animatefield=true,numframes=50,dirfield=300);

sys := D(x)(t)=y(t)-z(t),D(y)(t)=z(t)-x(t),D(z)(t)=x(t)-y(t)*2;

DEplot([sys],[x(t),y(t),z(t)],t=-2..2,[[x(0)=1,y(0)=0,z(0)=2]],
scene=[z(t),x(t)],method=classical[foreuler],stepsize=0.05);

de := cos(x)*diff(y(x),x$3)-diff(y(x),x$2)+Pi*diff(y(x),x)=y(x)-x;

DEplot(de,y(x),x=-2.5..1.4,[[y(0)=1,D(y)(0)=2,(D@@2)(y)(0)=1]],y=-4..5);

f := (x,y) -> x*(1-y-0.1*x): g := (x,y) -> 0.3*y*(x-1):

MLV:=[diff(x(t),t)=f(x(t),y(t)), diff(y(t),t) = g(x(t),y(t))];

solve({f(x,y)=0,g(x,y)=0},{x,y}); # the fixed points

ivs:=[[x(0)=1,y(0)=0.5],[x(0)=1,y(0)=1.5]];

DEplot(MLV,[x(t),y(t)],t=0..10,ivs,arrows=smalltwo,
dirfield=[12,12],color=magnitude[green,red]);

DEplot(MLV,[x(t),y(t)],t=-8..8,ivs,arrows=mediumfill,
color=[f(x(t),y(t)),g(x(t),y(t)),0.5],linecolor=t/2);

DEplot(MLV,[x(t),y(t)],t=0..10,ivs,arrows=comet,dirfield=200,
color=magnitude,linecolor=black);

DEplot(MLV,[x(t),y(t)],t=0..10,ivs,arrows=comet,dirfield=200,
size=magnitude,linecolor=[cyan,yellow],thickness=5);

DEplot(diff(y(x),x)=1/2*(-x-(x^2+4*y(x))^(1/2)),y(x),x=-3..3,y=-3..2,
  title=`Restricted domain`,color=1/2*(-x-(x^2+4*y)));

vdP := [diff(x(t),t)=10*(y(t)-x(t)^3/3+x(t)),diff(y(t),t)=-1/10*x(t)];

DEplot(vdP,[x(t),y(t)],t=0..20,x=-3..3,y=-2..2,[[x(0)=0.2,y(0)=0.2]],
  title=`van der Pol oscillator`,dirfield=400,arrows=comet,
  size=magnitude,numpoints=505,linecolor=blue,animatecurves=true);

DEplot(vdP,[x(t),y(t)],t=0..20,x=-2..2,y=-1..1,
  title=`van der Pol oscillator`,dirfield=[[0.2,0.2],[-0.2,-0.2]],
  arrows=comet,color=blue,animatefield=true,numframes=100);

DEplot([diff(x(t),t)=y(t),diff(y(t),t)=-sin(x(t))],[x(t),y(t)],
  t=0..10,[[x(0)=0,y(0)=.5],[x(0)=0,y(0)=1],[x(0)=0,y(0)=1.8],
  [x(0)=-2*Pi,y(0)=1],[x(0)=2*Pi,y(0)=.5],[x(0)=-2*Pi,y(0)=2.1],
  [x(0)=2*Pi,y(0)=-2.1]],title=`Pendulum Vibrations`,dirfield=300,
  arrows=comet,color=magnitude,linecolor=blue,animate=true);

r:=0.7*sqrt(x(t)^2+y(t)^2):

des:=[diff(x(t),t)=sin(r)*x(t)-y(t), diff(y(t),t)=sin(r)*y(t)+x(t)];

DEplot(des,[x(t),y(t)],t=0..2,x=-15..15,y=-15..15,color=magnitude,
  title=`Stable Limit Cycles`,arrows=curve,dirfield=800,axes=none);

DEplot(des,[x(t),y(t)],t=0..2,x=-15..15,y=-15..15,
  title=`Stable Limit Cycles`,arrows=comet,dirfield=300,animate=true);