 education - Maple Help

Maple dsolve in Education Description

 • Most of the intermediate solving steps used by Maple dsolve are now available as user level commands, including all the steps of the integrating factor and symmetry approaches.
 • New optional arguments in dsolve also permit you to tackle a given ODE using methods you specify, and with or without performing the integration step, facilitating the understanding of the different possible solving methods, and the use of dsolve and related Maple commands in classroom. ODEs can be classified

 • The relevant command is odeadvisor. The capability of classifying ODEs was introduced in Maple 5. In subsequent versions, the list of classifications known by the system was enlarged, focusing in classifications traditionally found in textbooks, and also in new ones related to solving algorithms recently presented in the literature. Example

 If infolevel is set to a greater integer (possible settings are 1 through 5), more detailed information about the computation method is displayed.
 > with(DEtools):
 > with(PDEtools, declare):
 > declare(y(x), prime=x); # Turn ON the enhanced DEdisplay feature
 ${y}{}\left({x}\right){}{\mathrm{will now be displayed as}}{}{y}$
 ${\mathrm{derivatives with respect to}}{}{x}{}{\mathrm{of functions of one variable will now be displayed with \text{'}}}$ (1)
 > infolevel[dsolve] := 3;
 ${{\mathrm{infolevel}}}_{{\mathrm{dsolve}}}{≔}{3}$ (2)
 > ode1 := diff(y(x), x)-y(x)^2+y(x)*sin(x)-cos(x);
 ${\mathrm{ode1}}{≔}{\mathrm{y\text{'}}}{-}{{y}}^{{2}}{+}{y}{}{\mathrm{sin}}{}\left({x}\right){-}{\mathrm{cos}}{}\left({x}\right)$ (3)
 This ODE is recognized by the system as of Riccati type
 $\left[{\mathrm{_Riccati}}\right]$ (4)
 and solved accordingly:
 > dsolve(ode1);
 Methods for first order ODEs: --- Trying classification methods --- trying a quadrature trying 1st order linear trying Bernoulli trying separable trying inverse linear trying homogeneous types: trying Chini differential order: 1; looking for linear symmetries trying exact Looking for potential symmetries trying Riccati trying Riccati sub-methods:    <- Riccati with symmetry of the form [0, exp(-Int(f,x))/P*(y*P-f)^2] successful
 ${y}{=}{-}\frac{{{ⅇ}}^{{-}{\mathrm{cos}}{}\left({x}\right)}}{\mathrm{c__1}{+}{\int }{{ⅇ}}^{{-}{\mathrm{cos}}{}\left({x}\right)}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}}{+}{\mathrm{sin}}{}\left({x}\right)$ (5)
 To know more about this type of ODE and related solving methods one can give the extra argument help:
 A table with all the classifications recognized in Maple is found at odeadvisor, classifications. Solutions using "this" or "that" method

 dsolve accepts extra arguments related to the solving method to be used (a single ODE can usually be solved using different methods); it is also possible to avoid the integration step, or avoid making the answer explicit; (these last two steps may easily obscure the whole solving process). Example

 A linear ODE
 > ode_L := sin(x)*diff(y(x), x)-cos(x)*y(x)=0;
 ${\mathrm{ode_L}}{≔}{\mathrm{y\text{'}}}{}{\mathrm{sin}}{}\left({x}\right){-}{y}{}{\mathrm{cos}}{}\left({x}\right){=}{0}$ (6)
 Although dsolve has its own strategy and defaults, one can also indicate to dsolve the use of any specific sequence of 'methods' to tackle the ODE. In this example the method for 'linear' ODEs is specified; in addition the optional argument 'useInt' makes dsolve not evaluating the integral appearing in the answer
 > dsolve(ode_L, [linear], useInt);
 Classification methods on request Methods to be used are: [linear] ---------------------------- * Tackling ODE using method: linear --- Trying classification methods --- trying 1st order linear <- 1st order linear successful
 ${y}{=}\mathrm{c__1}{}{{ⅇ}}^{{\int }{\mathrm{cot}}{}\left({x}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}}$ (7)
 Solutions like this one - before evaluating integrals - are useful to understand how the solution was obtained; integrals can be evaluated afterwards using value
 > value((7));
 ${y}{=}\mathrm{c__1}{}{\mathrm{sin}}{}\left({x}\right)$ (8)
 This particular linear ODE is also separable, hence it can also be solved via
 > dsolve(ode_L, [separable], useInt);
 Classification methods on request Methods to be used are: [separable] ---------------------------- * Tackling ODE using method: separable --- Trying classification methods --- trying separable <- separable successful
 ${\int }{\mathrm{cot}}{}\left({x}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}{-}\left({{\int }}_{{}}^{{y}}\frac{{1}}{{\mathrm{_a}}}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{\mathrm{_a}}\right){+}\mathrm{c__1}{=}{0}$ (9)
 > value((9));
 ${\mathrm{ln}}{}\left({\mathrm{sin}}{}\left({x}\right)\right){-}{\mathrm{ln}}{}\left({y}\right){+}\mathrm{c__1}{=}{0}$ (10) Integrating factors and ODEs

 • As a general alternative, ODEs can be tackled by looking for an integrating factor. The relevant commands in this approach are: intfactor, firint, firtest, muchange, mutest, adjoint. Example

 The linear first order ODE of the previous section can be solved by first determining an integrating factor for it
 > mu := intfactor(ode_L);
 ${\mathrm{\mu }}{≔}\frac{{1}}{{{\mathrm{sin}}{}\left({x}\right)}^{{2}}}$ (11)
 Integrating factors turn ODEs exact, that is: the product $\mathrm{\mu }$ times the ODE is a total derivative. One can combine the determination of an integrating factor with indicating to dsolve the use of the method for exact ODEs:
 > dsolve(mu * ode_L, [exact]);
 Classification methods on request Methods to be used are: [exact] ---------------------------- * Tackling ODE using method: exact --- Trying classification methods --- trying exact <- exact successful
 ${y}{=}{-}\frac{\mathrm{c__1}}{{\mathrm{csc}}{}\left({x}\right)}$ (12)
 > simplify(convert((12), sincos));
 ${y}{=}{-}\mathrm{c__1}{}{\mathrm{sin}}{}\left({x}\right)$ (13) Integrating factors for second and higher order linear ODEs

 • For linear ODEs (LODEs) of order 2 or greater, it is possible to calculate integrating factors by solving the adjoint of the LODE. This could be as difficult as the original problem, or much easier, depending on the example. The set of DEtools available permits a discussion of such a strategy in details. Example

 > ode := diff(y(x), x, x) = (y(x)*x+y(x)*ln(x)*x^2+diff(y(x), x)*ln(x)*x^2)/ln(x)/x^2*exp(x)- y(x)/ln(x)/x^2;
 ${\mathrm{ode}}{≔}{\mathrm{y\text{'}\text{'}}}{=}\frac{\left({y}{}{x}{+}{y}{}{\mathrm{ln}}{}\left({x}\right){}{{x}}^{{2}}{+}{\mathrm{y\text{'}}}{}{\mathrm{ln}}{}\left({x}\right){}{{x}}^{{2}}\right){}{{ⅇ}}^{{x}}}{{\mathrm{ln}}{}\left({x}\right){}{{x}}^{{2}}}{-}\frac{{y}}{{\mathrm{ln}}{}\left({x}\right){}{{x}}^{{2}}}$ (14)
 This ODE has the following adjoint
 ${-}\frac{\left({{ⅇ}}^{{x}}{}{x}{-}{1}\right){}{y}}{{\mathrm{ln}}{}\left({x}\right){}{{x}}^{{2}}}{+}{{ⅇ}}^{{x}}{}{\mathrm{y\text{'}}}{+}{\mathrm{y\text{'}\text{'}}}$ (15)
 This adjoint equation is in turn solvable by dsolve
 > dsolve((15));
 Methods for second order ODEs: --- Trying classification methods --- trying a symmetry of the form [xi=0, eta=F(x)]    <- BRANCH 2 successful. Symmetry is:, [0, exp(Int(1/x/ln(x),x))] <- linear_1 successful
 ${y}{=}\left(\left({\int }\frac{{{ⅇ}}^{{-}{{ⅇ}}^{{x}}}}{{{\mathrm{ln}}{}\left({x}\right)}^{{2}}}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}\right){}\mathrm{c__1}{+}\mathrm{c__2}\right){}{\mathrm{ln}}{}\left({x}\right)$ (16)
 Now the solutions to the adjoint equation are integrating factors of the original LODE, so the two independent solutions implied in the general solution above
 > eval(rhs((16)), {_C1=0, _C2=1});
 ${\mathrm{ln}}{}\left({x}\right)$ (17)
 > eval(rhs((16)), {_C1=1, _C2=2});
 $\left({\int }\frac{{{ⅇ}}^{{-}{{ⅇ}}^{{x}}}}{{{\mathrm{ln}}{}\left({x}\right)}^{{2}}}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}{+}{2}\right){}{\mathrm{ln}}{}\left({x}\right)$ (18)
 are integrating factors of ode. These integrating factors could also be found using the intfactor directly
 > Mu := intfactor(ode);
 trying a symmetry of the form [xi=0, eta=F(x)]<- linear_1 successful Trying an integrating factor as the solution to the adjoint linear ODE trying a symmetry of the form [xi=0, eta=F(x)] <- linear_1 successful
 ${\mathrm{The integrating factors are:}}{,}\left[{\mathrm{ln}}{}\left({x}\right){,}\left({\int }\frac{{{ⅇ}}^{{-}{{ⅇ}}^{{x}}}}{{{\mathrm{ln}}{}\left({x}\right)}^{{2}}}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}\right){}{\mathrm{ln}}{}\left({x}\right)\right]$
 ${\mathrm{Μ}}{≔}{\mathrm{ln}}{}\left({x}\right){,}\left({\int }\frac{{{ⅇ}}^{{-}{{ⅇ}}^{{x}}}}{{{\mathrm{ln}}{}\left({x}\right)}^{{2}}}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}\right){}{\mathrm{ln}}{}\left({x}\right)$ (19) Constructing solutions using integrating factors

 How are these integrating factors transformed into a solution to the original problem? By using them to construct two first integrals; that is: two ODEs of lower order (in this case two first order ODEs). For that purpose it is provided the firint command which receives an exact ODE and returns a first integral. The idea is simple: an exact ODE is a total derivative - say dR/dx; firint returns the R + _C1:
 > firint(Mu*ode);
 ${-}\frac{\left({\mathrm{ln}}{}\left({x}\right){}{{x}}^{{2}}{}{{ⅇ}}^{{x}}{+}{x}\right){}{y}}{{{x}}^{{2}}}{+}{\mathrm{ln}}{}\left({x}\right){}{\mathrm{y\text{'}}}{+}\mathrm{c__1}{=}{0}$ (20)
 > firint(Mu*ode);
 ${-}\frac{\left(\left({\int }\frac{{{ⅇ}}^{{-}{{ⅇ}}^{{x}}}}{{{\mathrm{ln}}{}\left({x}\right)}^{{2}}}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}\right){}{{\mathrm{ln}}{}\left({x}\right)}^{{2}}{}{{ⅇ}}^{{x}}{}{{x}}^{{2}}{+}\left({\int }\frac{{{ⅇ}}^{{-}{{ⅇ}}^{{x}}}}{{{\mathrm{ln}}{}\left({x}\right)}^{{2}}}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}\right){}{\mathrm{ln}}{}\left({x}\right){}{x}{+}{{ⅇ}}^{{-}{{ⅇ}}^{{x}}}{}{{x}}^{{2}}\right){}{y}}{{\mathrm{ln}}{}\left({x}\right){}{{x}}^{{2}}}{+}\left({\int }\frac{{{ⅇ}}^{{-}{{ⅇ}}^{{x}}}}{{{\mathrm{ln}}{}\left({x}\right)}^{{2}}}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}\right){}{\mathrm{ln}}{}\left({x}\right){}{\mathrm{y\text{'}}}{+}\mathrm{c__1}{=}{0}$ (21)
 Eliminating y' from these two first integrals (and replacing _C1 by _C2 in one of them) leads to the solution $f\left(x,y,\mathrm{c__1},\mathrm{c__2}\right)=0$ to this ode. So all this process could be ran interactively, as shown, or in one step
 > dsolve(ode);
 Methods for second order ODEs: --- Trying classification methods --- trying a symmetry of the form [xi=0, eta=F(x)] checking if the LODE is missing 'y' -> Heun: Equivalence to the GHE or one of its 4 confluent cases under 'a power @ Moebius' -> trying a solution of the form r0(x) * Y + r1(x) * Y' where Y = exp(int(r(x), dx)) * 2F1([a1, a2], [b1], f) -> Trying changes of variables to rationalize or make the ODE simpler    trying a symmetry of the form [xi=0, eta=F(x)]    checking if the LODE is missing 'y'    -> Heun: Equivalence to the GHE or one of its 4 confluent cases under 'a power @ Moebius'    -> trying a solution of the form r0(x) * Y + r1(x) * Y' where Y = exp(int(r(x), dx)) * 2F1([a1, a2], [b1], f)    -> Tackling the "Normal Form" of the given linear ODE:       trying a symmetry of the form [xi=0, eta=F(x)]    -> Tackling the linear ODE using alternative approaches:       trying 2nd order exact linear       trying symmetries linear in x and y(x)       trying to convert to a linear ODE with constant coefficients          testing BRANCH 1 ->    trying a symmetry of the form [xi=0, eta=F(x)]    checking if the LODE is missing 'y'    -> Heun: Equivalence to the GHE or one of its 4 confluent cases under 'a power @ Moebius'    -> trying a solution of the form r0(x) * Y + r1(x) * Y' where Y = exp(int(r(x), dx)) * 2F1([a1, a2], [b1], f)    -> Tackling the "Normal Form" of the given linear ODE:       trying a symmetry of the form [xi=0, eta=F(x)]    -> Tackling the linear ODE using alternative approaches:       trying 2nd order exact linear       trying symmetries linear in x and y(x)       trying to convert to a linear ODE with constant coefficients          testing BRANCH 1 -> <- unable to find a useful change of variables -> Tackling the "Normal Form" of the given linear ODE:    trying a symmetry of the form [xi=0, eta=F(x)] -> Tackling the linear ODE using alternative approaches:    trying 2nd order exact linear    trying symmetries linear in x and y(x)    trying to convert to a linear ODE with constant coefficients       testing BRANCH 1 ->    trying 2nd order, integrating factor of the form mu(x,y)    <- 2nd order, integrating factors of the form mu(x,y) successful
 ${y}{=}\mathrm{c__1}{}{{ⅇ}}^{{{ⅇ}}^{{x}}}{}{\mathrm{ln}}{}\left({x}\right){+}\mathrm{c__2}{}{{ⅇ}}^{{{ⅇ}}^{{x}}}{}\left({\int }\frac{{{ⅇ}}^{{-}{{ⅇ}}^{{x}}}}{{{\mathrm{ln}}{}\left({x}\right)}^{{2}}}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}\right){}{\mathrm{ln}}{}\left({x}\right)$ (22) Integrating factors for second and higher order nonlinear ODEs

 There are algorithms in dsolve for determining integrating factors for nonlinear ODEs too:
 • for second order ODEs, integrating factors depending on two variables (x, y) or (x, y') or (y, y') - when they exist - can be systematically determined;
 • for third order ODEs, integrating factors depending only on (y'') can also be systematically determined. Example

 > infolevel[dsolve] := 0;     # Turn OFF userinfos for dsolve
 ${{\mathrm{infolevel}}}_{{\mathrm{dsolve}}}{≔}{0}$ (23)
 > ode := diff(y(x), x, x, x) = -diff(y(x), x, x)^2/diff(y(x), x);
 ${\mathrm{ode}}{≔}{\mathrm{y\text{'}\text{'}\text{'}}}{=}{-}\frac{{{\mathrm{y\text{'}\text{'}}}}^{{2}}}{{\mathrm{y\text{'}}}}$ (24)
 For this ODE, three integrating factors are
 > intfactor((24));
 ${\mathrm{y\text{'}}}{,}{\mathrm{y\text{'}}}{}{x}{,}\frac{{1}}{{\mathrm{y\text{'}\text{'}}}}$ (25)
 The product of any of them times the ode is a total derivative, from where a first integral can be obtained; for instance taking the third one
 > firint((25) * ode);
 ${\mathrm{ln}}{}\left({\mathrm{y\text{'}}}\right){+}{\mathrm{ln}}{}\left({\mathrm{y\text{'}\text{'}}}\right){+}\mathrm{c__1}{=}{0}$ (26)
 Solving for y'' this reduced ODE,
 > isolate((26), diff(y(x), x, x));
 ${\mathrm{y\text{'}\text{'}}}{=}\frac{{1}}{{\mathrm{y\text{'}}}{}{{ⅇ}}^{\mathrm{c__1}}}$ (27)
 we are able to calculate more integrating factors (in this case intfactor succeeds again):
 > intfactor((27));
 ${\mathrm{y\text{'}}}$ (28)
 and obtain a lower order first integral as in the previous step
 > firint((28) * ((27)));
 ${{\mathrm{y\text{'}}}}^{{2}}{-}\frac{{2}{}{x}}{{{ⅇ}}^{\mathrm{c__1}}}{+}\mathrm{c__2}{=}{0}$ (29)
 Finally, this is a simple first order ODE which can be solved directly, leading to the general solution for the original ode problem:
 > dsolve((29));
 ${y}{=}{-}\frac{\left(\mathrm{c__2}{}{{ⅇ}}^{\mathrm{c__1}}{-}{2}{}{x}\right){}\sqrt{{-}{{ⅇ}}^{\mathrm{c__1}}{}\left(\mathrm{c__2}{}{{ⅇ}}^{\mathrm{c__1}}{-}{2}{}{x}\right)}}{{3}{}{{ⅇ}}^{\mathrm{c__1}}}{+}\mathrm{c__3}{,}{y}{=}\frac{\left(\mathrm{c__2}{}{{ⅇ}}^{\mathrm{c__1}}{-}{2}{}{x}\right){}\sqrt{{-}{{ⅇ}}^{\mathrm{c__1}}{}\left(\mathrm{c__2}{}{{ⅇ}}^{\mathrm{c__1}}{-}{2}{}{x}\right)}}{{3}{}{{ⅇ}}^{\mathrm{c__1}}}{+}\mathrm{c__3}$ (30)
 > map(odetest, [(30)], ode);
 $\left[{0}{,}{0}\right]$ (31)
 where in above we map the odetest command over each of the solutions. As a general comment, the integration constants entering the general solution of an ODE are arbitrary, we can always rename ${ⅇ}^{\mathrm{_C1}}\to \mathrm{_C1}$, simplifying a bit the solution. This ode here solved using the integrating factor approach can also be solved using the symmetry approach (following the steps shown in the next section).
 Also interesting in the integrating factor approach is the inverse problem; that is: to determine the most general ODE family having a given integrating factor (related worked examples are found in redode). The Lie symmetry approach for solving ODEs

 • dsolve includes symmetry methods for all differential order. The possibility of using separate tool-commands related to each of the symmetry steps makes approaching the method relatively easy. In addition, the possibility of also classifying the ODE according to standard methods, or looking for related integrating factors permits observing the natural relation existing among all these approaches. The most relevant related commands are symgen, canoni, transinv, reduce_order and buildsol; see also DEtools, Lie and dsolve, Lie. Example

 The following worked example aims at illustrating how the solving process can be performed step-by-step, using the symmetry approach, and with instructions easy to re-use. The commands to be used are: symgen (for calculating the symmetries), reduce_order (for reducing the order using these symmetries), and buildsol (to build the solution to the original problem from the solutions to the reduced ODE problems)
 This is a fifth order ODE (from Kamke's book, high order ODE example 17):
 > ode5 := 9*diff(y(x), x, x)^2*diff(y(x), x, x, x, x, x) - 45*diff(y(x), x, x)*diff(y(x), x, x, x)*diff(y(x), x, x, x, x) + 40*diff(y(x), x, x, x)=0;
 ${\mathrm{ode5}}{≔}{9}{}{{\mathrm{y\text{'}\text{'}}}}^{{2}}{}{\mathrm{y\text{'}\text{'}\text{'}\text{'}\text{'}}}{-}{45}{}{\mathrm{y\text{'}\text{'}}}{}{\mathrm{y\text{'}\text{'}\text{'}}}{}{\mathrm{y\text{'}\text{'}\text{'}\text{'}}}{+}{40}{}{\mathrm{y\text{'}\text{'}\text{'}}}{=}{0}$ (32)
 Classifying using odeadvisor (classifying ODEs is now a menu option available when "right clicking" on the ODE above)
 $\left[\left[{\mathrm{_high_order}}{,}{\mathrm{_missing_x}}\right]{,}\left[{\mathrm{_high_order}}{,}{\mathrm{_missing_y}}\right]{,}\left[{\mathrm{_high_order}}{,}{\mathrm{_with_linear_symmetries}}\right]\right]$ (33)
 it is apparent that there are various possible departure points to start reducing the ODE order: the ODE is missing the dependent and independent variables, it also has linear symmetries. In connection with all these starting points there are the symmetries:
 > X5 := symgen(ode5);
 ${\mathrm{X5}}{≔}\left[{\mathrm{_ξ}}{=}{0}{,}{\mathrm{_η}}{=}{1}\right]{,}\left[{\mathrm{_ξ}}{=}{1}{,}{\mathrm{_η}}{=}{0}\right]{,}\left[{\mathrm{_ξ}}{=}{0}{,}{\mathrm{_η}}{=}{x}\right]{,}\left[{\mathrm{_ξ}}{=}{1}{,}{\mathrm{_η}}{=}{x}\right]{,}\left[{\mathrm{_ξ}}{=}\frac{{x}}{{3}}{,}{\mathrm{_η}}{=}{y}\right]$ (34)
 The result above means, basically, that dsolve is able to solve the ODE by itself. With the purpose of illustrating the method, these symmetries are used below interactively to solve the ODE. The simplest manner of doing that is: reduce the order of the ODE by one and restart the discussion around this reduced ODE. When this approach is successful, build the solution to the original problem from the solution to the last reduced ODE. The steps below can be re-used with others ODE examples, as for instance the one solved interactively in the previous section by using integrating factors.
 So we start reducing the order using just one of the symmetries above
 > OFF;    # Turn OFF the enhanced DEdisplay feature
 > R_5_to_4 := reduce_order(ode5, X5, u(t));
 ${\mathrm{R_5_to_4}}{≔}{y}{}\left({x}\right){=}\left({\int }{u}{}\left({t}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{t}{+}\mathrm{c__1}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{&where}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}\left[\left\{\frac{{{ⅆ}}^{{4}}}{{ⅆ}{{t}}^{{4}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right){=}\frac{{5}{}\left(\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{t}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right)\right){}\left(\frac{{{ⅆ}}^{{3}}}{{ⅆ}{{t}}^{{3}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right)\right)}{\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right)}{-}\frac{{40}{}\left(\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{t}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right)\right)}{{9}{}{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right)\right)}^{{2}}}\right\}{,}\left\{{t}{=}{x}{,}{u}{}\left({t}\right){=}\frac{{ⅆ}}{{ⅆ}{x}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{y}{}\left({x}\right)\right\}{,}\left\{{x}{=}{t}{,}{y}{}\left({x}\right){=}{\int }{u}{}\left({t}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{t}{+}\mathrm{c__1}\right\}\right]$ (35)
 The structure of the solution above contains the answer in terms of a new function, u(t), which satisfy the fourth order differential equation being shown.
 Now select this fourth order ODE and consider the same cycle again (finding symmetries plus reducing its order again):
 > ode4 := op([2, 2, 1, 1], R_5_to_4);
 ${\mathrm{ode4}}{≔}\frac{{{ⅆ}}^{{4}}}{{ⅆ}{{t}}^{{4}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right){=}\frac{{5}{}\left(\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{t}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right)\right){}\left(\frac{{{ⅆ}}^{{3}}}{{ⅆ}{{t}}^{{3}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right)\right)}{\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right)}{-}\frac{{40}{}\left(\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{t}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right)\right)}{{9}{}{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right)\right)}^{{2}}}$ (36)
 > X4 := symgen(ode4);
 ${\mathrm{X4}}{≔}\left[{\mathrm{_ξ}}{=}{0}{,}{\mathrm{_η}}{=}{1}\right]{,}\left[{\mathrm{_ξ}}{=}{1}{,}{\mathrm{_η}}{=}{0}\right]{,}\left[{\mathrm{_ξ}}{=}{1}{,}{\mathrm{_η}}{=}{1}\right]{,}\left[{\mathrm{_ξ}}{=}\frac{{t}}{{2}}{,}{\mathrm{_η}}{=}{u}\right]$ (37)
 With the symmetries of ode4 in hands we can proceed in the same way to obtain a reduction of order from 4 to 3, now expressing the third order differential equation in terms of a new function s(r)
 > R_4_to_3 := reduce_order(ode4, X4, s(r));
 ${\mathrm{R_4_to_3}}{≔}{u}{}\left({t}\right){=}\left({\int }{s}{}\left({r}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{r}{+}\mathrm{c__1}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{&where}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}\left[\left\{\frac{{{ⅆ}}^{{3}}}{{ⅆ}{{r}}^{{3}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{s}{}\left({r}\right){=}\frac{{5}{}\left(\frac{{ⅆ}}{{ⅆ}{r}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{s}{}\left({r}\right)\right){}\left(\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{r}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{s}{}\left({r}\right)\right)}{{s}{}\left({r}\right)}{-}\frac{{40}{}\left(\frac{{ⅆ}}{{ⅆ}{r}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{s}{}\left({r}\right)\right)}{{9}{}{{s}{}\left({r}\right)}^{{2}}}\right\}{,}\left\{{r}{=}{t}{,}{s}{}\left({r}\right){=}\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}\right)\right\}{,}\left\{{t}{=}{r}{,}{u}{}\left({t}\right){=}{\int }{s}{}\left({r}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{r}{+}\mathrm{c__1}\right\}\right]$ (38)
 Selecting the third order ODE and calculating its symmetries leads to
 > ode3 := op([2, 2, 1, 1], R_4_to_3);
 ${\mathrm{ode3}}{≔}\frac{{{ⅆ}}^{{3}}}{{ⅆ}{{r}}^{{3}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{s}{}\left({r}\right){=}\frac{{5}{}\left(\frac{{ⅆ}}{{ⅆ}{r}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{s}{}\left({r}\right)\right){}\left(\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{r}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{s}{}\left({r}\right)\right)}{{s}{}\left({r}\right)}{-}\frac{{40}{}\left(\frac{{ⅆ}}{{ⅆ}{r}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{s}{}\left({r}\right)\right)}{{9}{}{{s}{}\left({r}\right)}^{{2}}}$ (39)
 > X3 := symgen(ode3);
 ${\mathrm{X3}}{≔}\left[{\mathrm{_ξ}}{=}{1}{,}{\mathrm{_η}}{=}{0}\right]{,}\left[{\mathrm{_ξ}}{=}{r}{,}{\mathrm{_η}}{=}{s}\right]$ (40)
 These symmetries can be used to reduced the order further, obtaining a second order ODE - we choose z(v) as new unknown function:
 > R_3_to_2 := reduce_order(ode3, X3, z(v));
 ${\mathrm{R_3_to_2}}{≔}{s}{}\left({r}\right){=}{v}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{&where}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}\left[\left\{\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{v}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{z}{}\left({v}\right){=}\frac{{3}{}{\left(\frac{{ⅆ}}{{ⅆ}{v}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{z}{}\left({v}\right)\right)}^{{2}}}{{z}{}\left({v}\right)}{+}\frac{{40}{}{{z}{}\left({v}\right)}^{{3}}}{{9}{}{{v}}^{{2}}}{+}\frac{{5}{}\left(\frac{{ⅆ}}{{ⅆ}{v}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{z}{}\left({v}\right)\right)}{{v}}\right\}{,}\left\{{v}{=}{s}{}\left({r}\right){,}{z}{}\left({v}\right){=}\frac{{1}}{\frac{{ⅆ}}{{ⅆ}{r}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{s}{}\left({r}\right)}\right\}{,}\left\{{r}{=}{\int }{z}{}\left({v}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{v}{+}\mathrm{c__1}{,}{s}{}\left({r}\right){=}{v}\right\}\right]$ (41)
 > ode2 := op([2, 2, 1, 1], R_3_to_2);
 ${\mathrm{ode2}}{≔}\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{v}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{z}{}\left({v}\right){=}\frac{{3}{}{\left(\frac{{ⅆ}}{{ⅆ}{v}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{z}{}\left({v}\right)\right)}^{{2}}}{{z}{}\left({v}\right)}{+}\frac{{40}{}{{z}{}\left({v}\right)}^{{3}}}{{9}{}{{v}}^{{2}}}{+}\frac{{5}{}\left(\frac{{ⅆ}}{{ⅆ}{v}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{z}{}\left({v}\right)\right)}{{v}}$ (42)
 One more cycle reduce the problem to a first order linear ODE which is a problem having solution in the general case in terms of integrals
 > X2 := symgen(ode2);
 ${\mathrm{X2}}{≔}\left[{\mathrm{_ξ}}{=}{0}{,}{\mathrm{_η}}{=}{{z}}^{{3}}\right]{,}\left[{\mathrm{_ξ}}{=}{v}{,}{\mathrm{_η}}{=}{0}\right]$ (43)
 > R_2_to_1 := reduce_order(ode2, X2, a(b));
 ${\mathrm{R_2_to_1}}{≔}{z}{}\left({v}\right){=}\left(\sqrt{{-}\frac{{1}}{{2}{}\left({\int }{a}{}\left({b}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{b}{+}\mathrm{c__1}\right)}}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{&where}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}\left[\left\{\frac{{ⅆ}}{{ⅆ}{b}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{a}{}\left({b}\right){=}\frac{{5}{}{a}{}\left({b}\right)}{{b}}{+}\frac{{40}}{{9}{}{{b}}^{{2}}}\right\}{,}\left\{{b}{=}{v}{,}{a}{}\left({b}\right){=}\frac{\frac{{ⅆ}}{{ⅆ}{v}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{z}{}\left({v}\right)}{{{z}{}\left({v}\right)}^{{3}}}\right\}{,}\left\{{v}{=}{b}{,}{z}{}\left({v}\right){=}\sqrt{{-}\frac{{1}}{{2}{}\left({\int }{a}{}\left({b}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{b}{+}\mathrm{c__1}\right)}}\right\}\right]$ (44)
 > ode1 := op([2, 2, 1, 1], R_2_to_1);
 ${\mathrm{ode1}}{≔}\frac{{ⅆ}}{{ⅆ}{b}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{a}{}\left({b}\right){=}\frac{{5}{}{a}{}\left({b}\right)}{{b}}{+}\frac{{40}}{{9}{}{{b}}^{{2}}}$ (45)
 The answer to this easy ODE found at the end of the reduction process is
 > sol1 := dsolve(ode1);
 ${\mathrm{sol1}}{≔}{a}{}\left({b}\right){=}\left({-}\frac{{20}}{{27}{}{{b}}^{{6}}}{+}\mathrm{c__1}\right){}{{b}}^{{5}}$ (46)
 Now, how could we build the solution to the original fifth order ode5? As follows: first use this solution above to build the solution to ode2 (the second order ODE one step above and rename integration constants which appeared as _C1 in all reductions):
 > buildsol(subs(_C1=_C2, R_2_to_1), sol1);
 ${z}{}\left({v}\right){=}\sqrt{{-}\frac{{1}}{{2}{}\left({\int }\left({{v}}^{{5}}{}\mathrm{c__1}{-}\frac{{20}}{{27}{}{v}}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{v}{+}\mathrm{c__2}\right)}}$ (47)
 The integral can be evaluated via
 > sol2 := value((47));
 ${\mathrm{sol2}}{≔}{z}{}\left({v}\right){=}\sqrt{{-}\frac{{1}}{{2}{}\left({-}\frac{{20}{}{\mathrm{ln}}{}\left({v}\right)}{{27}}{+}\frac{\mathrm{c__1}{}{{v}}^{{6}}}{{6}}{+}\mathrm{c__2}\right)}}$ (48)
 And now repeat the process until arriving at the solution to the original fifth order ode
 > sol3 := buildsol(subs(_C1=_C3, R_3_to_2), sol2);
 ${\mathrm{sol3}}{≔}{s}{}\left({r}\right){=}{\mathrm{RootOf}}{}\left({-}{r}{+}{3}{}\sqrt{{3}}{}\left({{\int }}_{{}}^{{\mathrm{_Z}}}\sqrt{{-}\frac{{1}}{{9}{}\mathrm{c__1}{}{{\mathrm{_a}}}^{{6}}{-}{40}{}{\mathrm{ln}}{}\left({\mathrm{_a}}\right){+}{54}{}\mathrm{c__2}}}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{\mathrm{_a}}\right){+}\mathrm{c__3}\right)$ (49)
 > sol4 := buildsol(subs(_C1=_C4, R_4_to_3), sol3);
 ${\mathrm{sol4}}{≔}{u}{}\left({t}\right){=}{\int }{\mathrm{RootOf}}{}\left({-}{t}{+}{3}{}\sqrt{{3}}{}\left({{\int }}_{{}}^{{\mathrm{_Z}}}\sqrt{{-}\frac{{1}}{{9}{}\mathrm{c__1}{}{{\mathrm{_a}}}^{{6}}{-}{40}{}{\mathrm{ln}}{}\left({\mathrm{_a}}\right){+}{54}{}\mathrm{c__2}}}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{\mathrm{_a}}\right){+}\mathrm{c__3}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{t}{+}\mathrm{c__4}$ (50)
 > sol5 := buildsol(subs(_C1=_C5, R_5_to_4), sol4);
 ${\mathrm{sol5}}{≔}{y}{}\left({x}\right){=}{\int }\left({\int }{\mathrm{RootOf}}{}\left({-}{x}{+}{3}{}\sqrt{{3}}{}\left({{\int }}_{{}}^{{\mathrm{_Z}}}\sqrt{{-}\frac{{1}}{{9}{}\mathrm{c__1}{}{{\mathrm{_a}}}^{{6}}{-}{40}{}{\mathrm{ln}}{}\left({\mathrm{_a}}\right){+}{54}{}\mathrm{c__2}}}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{\mathrm{_a}}\right){+}\mathrm{c__3}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}{+}\mathrm{c__4}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}{+}\mathrm{c__5}$ (51)
 This result can be tested using odetest
 > odetest(sol5, ode5);
 ${0}$ (52)
 For more examples see dsolve, Lie, , reduce_order and the help pages linked from DEtools, Lie.
 • Also interesting in the symmetry approach is the inverse problem; that is: to determine the most general ODE family having given symmetries (see equinv), or the symmetries of an 'unknown' ODE when its solution is given (see buildsym). Combining these two tools it is possible to depart from the form of the solution and arrive at the most general ODE problem having the symmetries of that type of solution (examples are found in the mentioned help-pages). Singular solutions for nonlinear ODEs

 • In addition to the general solution, Nonlinear ODEs may also have singular solutions (see references). When the ODE is polynomial in the unknown function y(x) and its derivatives, these singular solutions can be obtained separately by first splitting the ODE problem into cases. For example, consider
 > ON;     # Turn ON the enhanced DEdisplay
 > ode := (y(x)*diff(y(x), x, x)-diff(y(x), x)^2)*diff(y(x), x, x, x, x)-diff(y(x), x, x)^3 -y(x)*diff(y(x), x, x, x)^2+2*diff(y(x), x)*diff(y(x), x, x)*diff(y(x), x, x, x);
 ${\mathrm{ode}}{≔}\left({y}{}{\mathrm{y\text{'}\text{'}}}{-}{{\mathrm{y\text{'}}}}^{{2}}\right){}{\mathrm{y\text{'}\text{'}\text{'}\text{'}}}{-}{{\mathrm{y\text{'}\text{'}}}}^{{3}}{-}{y}{}{{\mathrm{y\text{'}\text{'}\text{'}}}}^{{2}}{+}{2}{}{\mathrm{y\text{'}}}{}{\mathrm{y\text{'}\text{'}}}{}{\mathrm{y\text{'}\text{'}\text{'}}}$ (53)
 The set of general and singular solutions to this ODE is given by the union of the non-singular solutions to each of the following ODEs:
 > casesplit(ode);
 $\left[{\mathrm{y\text{'}\text{'}\text{'}\text{'}}}{=}\frac{{y}{}{{\mathrm{y\text{'}\text{'}\text{'}}}}^{{2}}{-}{2}{}{\mathrm{y\text{'}}}{}{\mathrm{y\text{'}\text{'}}}{}{\mathrm{y\text{'}\text{'}\text{'}}}{+}{{\mathrm{y\text{'}\text{'}}}}^{{3}}}{{y}{}{\mathrm{y\text{'}\text{'}}}{-}{{\mathrm{y\text{'}}}}^{{2}}}\right]\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{&where}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}\left[{y}{}{\mathrm{y\text{'}\text{'}}}{-}{{\mathrm{y\text{'}}}}^{{2}}{\ne }{0}\right]{,}\left[{\mathrm{y\text{'}\text{'}}}{=}\frac{{{\mathrm{y\text{'}}}}^{{2}}}{{y}}\right]\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{&where}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}\left[{y}{\ne }{0}\right]{,}\left[{y}{=}{0}\right]\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{&where}\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}\left[\right]$ (54)
 In above we see three cases. The first one, which has the same differential order of the original problem ode leads to the general solution. The two second cases are of lower differential order and lead to singular solutions. So for this example dsolve returns
 > dsolve(ode);
 ${y}{=}\frac{{\left({{ⅇ}}^{\frac{\sqrt{{\mathrm{c__1}}^{{2}}{+}{4}{}\mathrm{c__2}}{}\left(\mathrm{c__3}{+}{x}\right)}{{2}}}\right)}^{{2}}{+}{1}}{{2}{}{{ⅇ}}^{\frac{\mathrm{c__3}{}\sqrt{{\mathrm{c__1}}^{{2}}{+}{4}{}\mathrm{c__2}}}{{2}}{+}\frac{\sqrt{{\mathrm{c__1}}^{{2}}{+}{4}{}\mathrm{c__2}}{}{x}}{{2}}{-}\frac{{x}{}\mathrm{c__1}}{{2}}{-}\mathrm{c__4}}}$ (55)
 In some cases (e.g.: the one above) some of the singular solutions can be obtained by adjusting the integration constants in the other solutions (general or singular).