restart:

with(Maplets[Elements]):

M := <<1,2,3>|<2,3,5>|<3,5,12>>;

# Define the Maplet application.
maplet := Maplet(BoxLayout('vertical'=true,

    # A paragraph describing the matrix norm.
    TextBox( "A matrix norm is a function ||.|| which satisfies all the "
             "properties of a norm and also ||M.N|| <= ||M||*||N|| where M "
             "and N are matrices.",
             'height' = 3, 'width' = 35, 'editable' = 'false' ),

    # Three rows, each requesting the user for various
    # forms of input.  The first check box has a default
    # value determined by the return value of a Maple call.
    # The second check box is selected by default.

    BoxRow(
       BoxCell( "Norm:", 'halign'='left' ),
       BoxCell( DropDownBox['DDB1'](["infinity", "1", "Euclidean (2)",
                "Frobenius"]), 'halign'='right' )
    ),
    BoxRow(
       BoxCell( "Matrix has real entries:", 'halign'='left' ),
       BoxCell( CheckBox['ChB1'](not has(M, I)), 'halign'='right' )
    ),
    BoxRow(
       BoxCell( "Evaluate result:", 'halign'='left' ),
       BoxCell( CheckBox['ChB2'](true), 'halign'='right' )
    ),

    BoxRow(
       # The OK button shuts down the Maplet application and
       # returns the results in the drop-down and check boxes.
       BoxCell( Button("OK", Shutdown(['DDB1', 'ChB1', 'ChB2'])), 'halign'='left' ),

       # The Cancel button shuts down the Maplet application
       # without returning any results.
       BoxCell( Button("Cancel", Shutdown()), 'halign'='right' )
    )
)):

# Display runs the Maplet application.
result := Maplets[Display](maplet);

if type( result, list ) then
    continue := true;

    n := subs( ["infinity" = infinity, "1" = 1, "Euclidean (2)" = 2, "Frobenius" = Frobenius], result[1] );
    c := not parse( result[2] );
    er := parse( result[3] );
else
    continue := false;
end if:

if continue then
    if er then
        answer := LinearAlgebra[MatrixNorm]( M, n, conjugate = c );
    else
        answer := ''LinearAlgebra[MatrixNorm]''( M, n, conjugate = c );
    end if;
end if:

answer;

?Maplets,Examples,MatrixNorm

print( Maplets[Examples][LinearAlgebra][MatrixNorm] );