 Application Center - Maplesoft

# The Doppler Effect

You can switch back to the summary page by clicking here.

doppler.mws

The Doppler Effect

By Sylvain Muise

<smuise@student.math.uwaterloo.ca>

Introduction

Suppose you are standing on a sidewalk as a car passes you on the street blowing its horn at a frequency of 440Hz the whole way. As the car approaches you, you will hear a pitch higher than 440Hz, and after the car passes you and drives away from you, you will hear a pitch lower than 440Hz. This phenomenon, called the Doppler Effect, is a shift in the frequency and wavelength of waves, including sound and light, resulting from relative motion between the source of the wave and the medium. If the source and receiver approach each other, the perceived frequency will be higher. If they're separating, the perceived frequency will be lower.
This Maple application demonstrates the physics behind the Doppler Effect using animations. We'll illustrate five distinct cases:
1. A motionless source.
2. A source moving at a constant velocity less than the speed of the wave.
3. A source moving at exactly the same speed as the wave.
4. A source moving at a constant velocity greater than the speed of the wave.
5. A source accelerating above the speed of the wave.

Code

> restart:
with(plots):
with(plottools):

```Warning, the name changecoords has been redefined
```

```Warning, the name arrow has been redefined
```

> wave := proc(n,initSpeed,finalSpeed)
local i, li, j, circles, se, source, slope:
slope := (finalSpeed - initSpeed) / n:
for i from 0 to n*4 do
li := NULL:
for j from 1 to n do
if i > (j-1)*4 then
circles[j][i] := circle([initSpeed * (j-1) + 0.5 * slope * (j-1)^2, 0], (i-(j-1)*4) / 4):
li := circles[j][i], li:
end if:
end do:
source := point([initSpeed * i/4 + 0.5 * slope * (i/4)^2, 0], color=blue, symbol=circle, symbolsize=12):
animation||i := display([li, source]):
end do:
se := animation||(0..n*4):
end proc:

1. A motionless source.

This is a view of a stationary sound source. The circles could represent the peaks of the sound waves, so the distance between the circles is the wavelength.

> wave1 := wave(10,0,0):

> display(wave1,insequence=true,scaling=constrained, axes=none); 2. A source moving at a constant velocity less than the speed of the wave.

This is an animation of a sound source moving towards the right, at a speed lower than the speed of the wave. The circles on the right of the source are closer together, hence the wavelength of the produced wave is shorter than what the source would actually produce if it were stationary.

Because of the relationship , wavelength and frequency are inversely proportional: . Therefore, since the wavelength is shorter on the right side of the source, the frequency is higher on that side. Similarly, the frequency is lower on the left side of the source.

That is why the pitch of the car horn is higher when the car approaches you, and is lower when the car drives away from you.

> wave2 := wave(10,0.5,0.5):

> display(wave2,insequence=true,scaling=constrained, axes=none); 3. A source moving at exactly the same speed as the wave.

In the following animation, the source is travelling at exactly the same speed as the wave. If this were a jet plane, its speed would be exactly the speed of sound, or Mach 1, approximately 340 m/s. An observer on the right of the source wouldn't actually hear anything until the source itself reached him/her. The sound wouldn't be perceived as a pitch either, but simply as a big thump, because of all the built up sound waves. The pressure front is quite intense, producing a shock wave. This wall is referred to as the sound barrier when a jet passes into supersonic speeds.

> wave3 := wave(10,1,1):

> display(wave3,insequence=true,scaling=constrained, axes=none); 4. A source moving at a constant velocity greater than the speed of the wave.

In the following animation, the source is moving faster than the sound itself. This could be a jet travelling at supersonic speeds. An observer would see the plane pass overhead, and then a few seconds later would be hit by the shock wave produced by all the sound waves behind the jet. When the jet travels at a constant velocity, the shape of the shockwave left behind it is a cone, which is elongated the faster the jet is moving. If the jet is accelerating at a constant rate, as is shown in the next animation, the shape of the cone/shock wave is distorted.

> wave4 := wave(10,1.5,1.5):

> display(wave4,insequence=true,scaling=constrained, axes=none); 5. A source accelerating above the speed of the wave.

In this animation, you can see the jet accelerating from subsonic speeds through to supersonic speeds.

> wave5 := wave(15,0.5,2.5):

> display(wave5,insequence=true,scaling=constrained, axes=none); Conclusions

The perceived frequency, , is related to the actual frequency, , the velocity of the source, , the velocity of the observer, , and the velocity of the wave, . If the source and the observer are moving towards each other, must be greater, and is given by .

If the source and the observer are moving away from each other, must be less, and is given by .

(Notice the difference in the '+' and '-')