Application Center - Maplesoft
  Submit your work
Application Center Applications 2D-heat equation, steady flows Preview

App Preview:

2D-heat equation, steady flows

You can switch back to the summary page by clicking here.

Learn about Maple
Download Application

 

2DHeat.mws

Section 11.5. The 2D-Heat Equation
Steady Flows

by Alain Goriely, goriely@math.arizona.edu,
(http://www.math.arizona.edu/~goriely)

Abstract: This section illustrates Section 11.5 in Kreyszig 's book (8th ed.)

Application Areas/Subjects: Engineering, Applied Mathematics

Keywords: Heat equation, 2D, steady flows, Fourier series
See Also:  Other Worksheets in the same package.

Prerequisites:  plots

Note:  Send me an e-mail (comments-criticisms) if you use this worksheet.

> restart;assume(n,integer):with(plots):
setoptions(thickness=2): #set the tickness of the lines in the plots

Warning, the name changecoords has been redefined

Introduction

In this worksheet, I use Maple to illustrate Section 11.5 of Kreyszig 's book: Advanced Engineering Mathematics.

Let u = u(x, y, t) be the temperature in a two dimensional media. The heat profile obeys the following PDEs
(the so-called 2D heat equation):

diff(u, t) = c^2*((diff(u, `$`(x, 2)))+(diff(u, `$`(y, 2))))

where c  is the diffusion constant  (c^2 = K/(sigma*rho) : themal conductivity/ (specific heat *density) )

We consider stationary profiles, that is time-independent solutions of the heat equations. These represent steady heat flows in 2D. Hence, we have, the LAPLACE EQUATION:

(diff(u, `$`(x, 2)))+(diff(u, `$`(y, 2))) = 0

We are looking for a steady flow in a rectangle in the (x, y ) plane with the following boundary conditions

u(0, y) = 0   and   u(a, y) = 0

u(x, 0) = 0   and   u(x, b) = f(x)

Here we explore different steady solutions of the heat equation in 2D, starting with initial heat profile on one side.


Look at the 3D Plots!

Section 1: The eigenfunctions

> Su:=u=(A[n]*sin(n*Pi*x/a)*sinh(n*Pi*y/a));

Su := u = A[n]*sin(n*Pi*x/a)*sinh(n*Pi*y/a)

Let us verify that this is indeed a solution of the equation:

> Diff(u,x$2) + Diff(u,`$`(y,2))=eval(subs(Su,diff(u,`$`(x,2))+diff(u,`$`(y,2))));

(Diff(u, `$`(x, 2)))+(Diff(u, `$`(y, 2))) = 0

We want to see what these modes look like: Start with n=1, the FUNDAMENTAL solution:

The fundamental eigenfunction

> M1:=subs(n=1,a=2*Pi,b=Pi,c=2,subs(Su,A[n]=1,u));

> plot3d( M1,x=0..2*Pi,y=0..Pi,shading=zhue,title="Fundamental eigenfunction for 2D steady heat flow",orientation=[-118,43],axes=boxed,style=patchnogrid,lightmodel=light2);

M1 := sin(1/2*x)*sinh(1/2*y)

[Plot]

The other eigenfunctions

> M1:=subs(n=2,a=2*Pi,b=Pi,c=2,subs(Su,A[n]=1,u));

> plot3d( M1,x=0..2*Pi,y=0..Pi,shading=zhue,title="n=2 eigenfunction for 2D steady heat flow",orientation=[48,53],axes=boxed,style=patchnogrid,lightmodel=light2);

M1 := sin(x)*sinh(y)

[Plot]

> M1:=subs(n=3,a=2*Pi,b=Pi,c=2,subs(Su,A[n]=1,u));

> plot3d( M1,x=0..2*Pi,y=0..Pi,shading=zhue,title="n=3 eigenfunction for 2D steady heat flow",orientation=[48,53],axes=boxed,style=patchnogrid,lightmodel=light2);

M1 := sin(3/2*x)*sinh(3/2*y)

[Plot]

The modes n >1 all have a negative part. Therefore, as such they are not physical solutions of the heat equations. However, the superposition of these eigenfunctions are solutions (as long as 0 < u(x, y) ).

Section 2: An example of a symmetric profile

We now take a simple profile for f(x) and look at the steady flow"

> f(x)=(1-cos(x));plot((1-cos(x)),x=0..2*Pi,thickness=3);

f(x) = 1-cos(x)

[Plot]

> A:=2/(2*Pi*sinh(m*Pi*Pi/2/Pi))*int((1-cos(x))*sin(m*x/2),x=0..2*Pi);

A := 8*(-1+cos(m*Pi))/(Pi*sinh(1/2*m*Pi)*m*(m^2-4))

> S:=(N,x)->subs(m=1,A)*sin(x/2)*sinh(y/2)+
         sum(subs(m=k,A)*sin(k*x/2)*sinh(k*y/2),k=3..N):
St:=S(10,x):

> plot3d( St,x=0..2*Pi,y=0..Pi,shading=zhue,title="2D steady heat flow: Red=HOT, purple=COLD",orientation=[-90,0],axes=boxed,style=patchnogrid);

[Plot]

> plot3d( St,x=0..2*Pi,y=0..Pi,shading=zhue,title="2D steady heat flow: Red=HOT, purple=COLD",orientation=[-122,44],axes=boxed,style=patchnogrid,lightmodel=light2);

[Plot]

Section 3: An asymmetric profile

> f:=(sin(x/2)-1/2*sin(x));plot(f,x=0..2*Pi,thickness=3,color=blue);

f := sin(1/2*x)-1/2*sin(x)

[Plot]

> A1:=1/sinh(Pi/2):A2:=-1/2/sinh(Pi):S:=A1*sin(x/2)*sinh(y/2)+A2*sin(x)*sinh(y);

S := sin(1/2*x)*sinh(1/2*y)/sinh(1/2*Pi)-1/2*sin(x)*sinh(y)/sinh(Pi)

> plot3d( S,x=0..2*Pi,y=0..Pi,shading=zhue,title="2D steady heat flow: Red=HOT, purple=COLD",orientation=[-90,0],axes=boxed,style=patchnogrid);

[Plot]

> plot3d( S,x=0..2*Pi,y=0..Pi,shading=zhue,title="2D steady heat flow: Red=HOT, purple=COLD",orientation=[-107,38],axes=boxed,style=patchnogrid,lightmodel=light2);

[Plot]

Section 4: Another asymmetric profile

> f:=(sin(x/2)-1/4*sin(4*x/2));plot(f,x=0..2*Pi,thickness=3,color=blue);

f := sin(1/2*x)-1/4*sin(2*x)

[Plot]

> A1:=1/sinh(Pi/2):A4:=-1/4/sinh(4*Pi/2):A3:=-1/5/sinh(3*Pi/2):
A5:=1/5/sinh(5*Pi/2):
S:=A1*sin(x/2)*sinh(y/2)+A4*sin(4*x/2)*sinh(4*y/2);

S := sin(1/2*x)*sinh(1/2*y)/sinh(1/2*Pi)-1/4*sin(2*x)*sinh(2*y)/sinh(2*Pi)

> plot3d( S,x=0..2*Pi,y=0..Pi,shading=zhue,title="2D steady heat flow: Red=HOT, purple=COLD",orientation=[-90,0],axes=boxed,style=patchnogrid);

[Plot]

> plot3d( S,x=0..2*Pi,y=0..Pi,shading=zhue,title="2D steady heat flow: Red=HOT, purple=COLD",orientation=[-107,38],axes=boxed,style=patchnogrid,lightmodel=light2);

[Plot]

>

References

E. Kreyszig : Advanced Engineering Mathematics (8th Edition) John Wiley  New York (1999)

Disclaimer: While every effort has been made to validate the solutions in this worksheet, Waterloo Maple Inc. and the contributors are not responsible for any errors contained and are not liable for any damages resulting from the use of this material.